#include <Keypad.h>
#include <LiquidCrystal_I2C.h>
#define POT A0
#define BUZZ 13
#define TRIGGERPIN 12
#define ECHOPIN 11

const uint8_t ROWS = 4;
const uint8_t COLS = 4;
char keys[ROWS][COLS] = {
  { '1', '2', '3', 'A' },
  { '4', '5', '6', 'B' },
  { '7', '8', '9', 'C' },
  { '*', '0', '#', 'D' }
};

uint8_t colPins[COLS] = { 6,5,4,3 }; // Pins connected to C1, C2, C3, C4
uint8_t rowPins[ROWS] = { 10,9,8,7 }; // Pins connected to R1, R2, R3, R4

LiquidCrystal_I2C lcd(0x27,20,4);
Keypad keypad = Keypad(makeKeymap(keys), rowPins, colPins, ROWS, COLS);

String code = "";
float distance = 0;
bool alarmOn = false;
char pressed;

void setup()
{
    Serial.begin(9600);
    pinMode(TRIGGERPIN, OUTPUT);
    pinMode(ECHOPIN, INPUT);
    pinMode(BUZZ, OUTPUT);
    lcd.init();
    lcd.backlight();
    lcd.print("-----> Alarm <-----");
    delay(2000);
    lcd.clear();
    if(code == ""){
      lcd.print("No code found!");
      code = getCode();
    }
}

void loop()
{
  
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Code selected,");
  lcd.setCursor(0, 1);
  lcd.print("choose an option: ");
  lcd.setCursor(5, 2);

  lcd.print("*: start");
  lcd.setCursor(5, 3);
  lcd.print("#: reset code");
  while(pressed != '*' && pressed != '#'){
    pressed = keypad.getKey();
  }
  switch (pressed){
    case '*':
      alarmOn = true;
      alarmIsArmed();
      break;
    case '#':
      code = getCode();
      break;
  }
}

void alarmIsArmed(){
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Alarm armed!");  
  delay(1000);
  int distanceThr = getDistanceThr();
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("A for turn off!");  
  lcd.setCursor(0, 1);
  lcd.print("DistanceThr: ");
  lcd.print(distanceThr); 
  lcd.print("cm"); 
  delay(1000);
  int checkAttempts = 0;
  while(alarmOn){
    pressed = keypad.getKey();
    if(getDistance() < distanceThr || checkAttempts >= 3){
      alarmIsOn();
    }
    if(pressed == 'A'){
      checkAttempts ++;
      if(checkCode(getCode(), code)){
        alarmOn = false;
      }else{
        lcd.clear();
        lcd.setCursor(0, 0);
        lcd.print("A for turn off!");  
        lcd.setCursor(0, 1);
        lcd.print("DistanceThr: ");
        lcd.print(distanceThr); 
        lcd.print("cm"); 
      }
    }
  }
}

void alarmIsOn(){
  startBuzz();
  lcd.clear();
  lcd.setCursor(0, 1);
  lcd.print("ALARM!"); 
  while(!checkCode(getCode(), code)){
  }
  alarmDeactivated();
}

void alarmDeactivated(){
  stopBuzz();
  lcd.clear();
  lcd.setCursor(0, 1);
  lcd.print("ALARM DEACTIVATED!");
  alarmOn = false;
  delay(2000);
}

bool checkCode(String codeIn, String codeSaved){
  return (codeIn == codeSaved) ? true : false;
}

float getDistanceThr(){
  return map(analogRead(POT), 0, 1023, 1, 350);
}

float getDistance(){
  digitalWrite(TRIGGERPIN, LOW);
	delayMicroseconds(2);
	digitalWrite(TRIGGERPIN, HIGH);
	delayMicroseconds(10);
	digitalWrite(TRIGGERPIN, LOW);

	return pulseIn(ECHOPIN, HIGH) / 58;
}

void startBuzz(){
  tone(BUZZ, 100);
}

void stopBuzz(){
  noTone(BUZZ);
}

String getCode(){
  String inCode;
  lcd.clear();
  lcd.setCursor(0, 1);
  lcd.print("Select 4 char: ");
  lcd.setCursor(6, 3);
  lcd.print("_ _ _ _");
  int count = 0;
  while(inCode.length() < 4){
    pressed = keypad.getKey();
    if(pressed != NO_KEY){
      lcd.setCursor(6 + (count * 2), 3);
      lcd.print(pressed);
      delay(200);
      lcd.setCursor(6 + (count * 2), 3);
      lcd.print("*");
      inCode += pressed;
      count ++;
    }
  }
  return inCode;
}