#include "DHT.h"
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <Servo.h>

#define DHTPIN 2          // Pin connecté au DHT22
#define DHTTYPE DHT22     // Type de capteur DHT
#define OLED_RESET -1     // Aucune broche de reset pour OLED
#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
#define HUMIDITY_LED_PIN 3  // LED pour humidité
#define TEMP_LED_PIN 4      // LED pour température
#define HUMIDITY_THRESHOLD 40  // Seuil d'humidité pour arrosage
#define SERVO_PIN 5         // Pin connecté au servo

// Création des objets DHT, OLED et Servo
DHT dht(DHTPIN, DHTTYPE);
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);
Servo servo; 

void setup() {
  Serial.begin(9600);   
  dht.begin();            

  pinMode(HUMIDITY_LED_PIN, OUTPUT); 
  pinMode(TEMP_LED_PIN, OUTPUT);    
  
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {  
    Serial.println(F("Échec de l'initialisation de l'écran OLED"));
    for (;;); 
  }
  
  servo.attach(SERVO_PIN); 
  servo.write(0);           // Position initiale du servo (0°)
  
  display.clearDisplay();  // Effacer l'écran au démarrage
  display.setTextColor(WHITE);  // Couleur du texte en blanc
}

void loop() {
  // Lire l'humidité et la température du DHT22
  float humidite = dht.readHumidity();
  float temperature = dht.readTemperature();

  // Vérifier si les lectures sont valides
  if (isnan(humidite) || isnan(temperature)) {
    Serial.println(F("Échec de lecture du capteur DHT22!"));
    return;
  }

  // Afficher les valeurs sur le moniteur série
  Serial.print(F("Humidité: "));
  Serial.print(humidite);
  Serial.print(F(" %\t"));
  Serial.print(F("Température: "));
  Serial.print(temperature);
  Serial.println(F(" °C"));

  // Contrôle des LEDs
  bool humidityLedState = false; // État de la LED d'humidité
  bool temperatureLedState = false; // État de la LED de température

  if (humidite < HUMIDITY_THRESHOLD) {  // Si l'humidité est inférieure au seuil
    digitalWrite(HUMIDITY_LED_PIN, HIGH);  // Allumer la LED d'humidité
    humidityLedState = true; // La LED d'humidité est allumée
  } else {
    digitalWrite(HUMIDITY_LED_PIN, LOW);   // Éteindre la LED d'humidité
  }

  if (temperature > 30) {  // Si la température est supérieure à 30°C
    digitalWrite(TEMP_LED_PIN, HIGH);      // Allumer la LED de température
    temperatureLedState = true; // La LED de température est allumée
  } else {
    digitalWrite(TEMP_LED_PIN, LOW);       // Éteindre la LED de température
  }

  // Vérification si les deux LEDs sont allumées
  if (humidityLedState && temperatureLedState) {
    servo.write(0);  // Ouvrir la pompe (position à 90°)
  } else {
    servo.write(90);  // Fermer la pompe (position à 0°)
  }

  // Afficher les données sur l'écran OLED
  display.clearDisplay();  // Effacer l'écran avant de nouvelles données
  display.setTextSize(1);  // Taille du texte
  display.setCursor(0, 0); // Position du texte

  display.print("Humidite: ");
  display.print(humidite);
  display.println(" %");
  
  display.print("Temperature: ");
  display.print(temperature);
  display.println(" C");

  // Vérification du besoin d'arrosage
  if (humidityLedState && temperatureLedState){
    display.setCursor(0, 40); // Position pour le message d'arrosage
    display.setTextSize(1);    // Taille du texte
     display.println("Conditions verifier !");
    display.println("Il faut faire arrosage!");
  }

  // Afficher les données sur l'écran
  display.display();
  
  delay(2000);  // Attendre 2 secondes avant la prochaine lecture
}