#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>

#define BUILTIN_LED 2
#define DHTPin 15
#define WIFI_SSID "Wokwi-GUEST"
#define WIFI_PASSWORD ""

const char* mqtt_server = "test.mosquitto.org";
 

WiFiClient espClient;
PubSubClient client(espClient);
unsigned long lastMsg = 0;
#define MSG_BUFFER_SIZE	(50)
char msg[MSG_BUFFER_SIZE];
int value = 0;
DHT dht(DHTPin, DHT22); 


void setup_wifi() {
  delay(10);
  // We start by connecting to a WiFi network
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(WIFI_SSID);

  WiFi.mode(WIFI_STA);
  WiFi.begin(WIFI_SSID, WIFI_PASSWORD);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  dht.begin();

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  Serial.println((char)payload[0]);

  // Switch on the LED if an 1 was received as first character
  if ((char)payload[0] == '0') {
    digitalWrite(BUILTIN_LED, LOW);  // Turn the LED off
    Serial.println("LED DESLIGADO");
  } else if ((char)payload[0] == '1') {
    digitalWrite(BUILTIN_LED, HIGH); // Turn the LED on
    Serial.println("LED LIGADO");
  }
}

void reconnect() {
  // Loop until we're reconnected
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // Create a random client ID
    String clientId = "ESP32Client-";
    clientId += String(random(0xffff), HEX);
    // Attempt to connect
    if (client.connect(clientId.c_str())) {
      Serial.println("connected");
      // Once connected, publish an announcement...
      client.publish("outOutTopic", "starting....");
      // ... and resubscribe
      client.subscribe("control/led");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void setup() {
  Serial.begin(115200);
  pinMode(BUILTIN_LED, OUTPUT);     // Initialize the LED pin as an output
  digitalWrite(BUILTIN_LED, LOW);  // Turn the LED off  Serial.begin(115200);
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();
  
  float humidity = dht.readHumidity();
  float temperature = dht.readTemperature();

  if (isnan(humidity) || isnan(temperature)) {
    Serial.println("Failed to read from DHT sensor!");
    return;
  }

  char tempString[15];
  char humString[15];
  sprintf(tempString, "%f", temperature);
  sprintf(humString, "%f", humidity);
  client.publish("sensor/temperature", tempString);
  client.publish("sensor/humidity", humString);
  Serial.println("Publishing: Temperature: " + String(temperature)+ " Humidity: " + String(humidity));

  delay(2000);
}