#include <Wire.h>
#include <Adafruit_MPU6050.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
#define OLED_RESET     -1
#define SCREEN_ADDRESS 0x3C

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);
Adafruit_MPU6050 mpu;

const int trigPin = 25;  // TRIG pin
const int echoPin = 26; // ECHO pin
const float SOUND_SPEED = 0.034;

void setup() {
  Serial.begin(115200);
  Wire.begin();

  if(!display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS)) {
    Serial.println(F("SSD1306 allocation failed"));
    for(;;);
  }
  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);

  if (!mpu.begin()) {
    Serial.println("MPU6050 not found");
    while (1) yield();
  }

  pinMode(trigPin, OUTPUT);
  pinMode(echoPin, INPUT);
}

float measureDistance() {
  digitalWrite(trigPin, LOW);
  delayMicroseconds(2);
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin, LOW);
  
  return pulseIn(echoPin, HIGH) * SOUND_SPEED / 2;
}

void loop() {
  sensors_event_t a, g, temp;
  mpu.getEvent(&a, &g, &temp);
  float distance = measureDistance();

  display.clearDisplay();
  display.setCursor(0, 0);
  display.print("Acc: ");
  display.print(a.acceleration.x);
  display.print(" ");
  display.print(a.acceleration.y);
  display.print(" ");
  display.println(a.acceleration.z);

  display.print("Gyr: ");
  display.print(g.gyro.x);
  display.print(" ");
  display.print(g.gyro.y);
  display.print(" ");
  display.println(g.gyro.z);

  display.print("Dist: ");
  display.print(distance);
  display.println(" cm");
  display.display();

  Serial.printf("Acc: %.2f %.2f %.2f | Gyr: %.2f %.2f %.2f | Dist: %.2f cm\n",
                a.acceleration.x, a.acceleration.y, a.acceleration.z,
                g.gyro.x, g.gyro.y, g.gyro.z, distance);

  delay(100);
}