#include <Adafruit_MPU6050.h>
#include <Adafruit_Sensor.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <Wire.h>
#define SOUND_SPEED 0.034 //define sound speed in cm/uS
#define CM_TO_INCH 0.393701

#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels


const int trigPin = 5;
const int echoPin = 18;

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1); // Declaration for an SSD1306 display connected to I2C (SDA, SCL pins)
Adafruit_MPU6050 mpu;
long duration;
float distanceCm;
float distanceInch;
void setup() {
  Serial.begin(115200); // Starts the serial communication
  pinMode(trigPin, OUTPUT); // Sets the trigPin as an Output
  pinMode(echoPin, INPUT); // Sets the echoPin as an Input

  while (!mpu.begin()) {
    Serial.println("MPU6050 not connected!");
    delay(500);
  }
  Serial.println("MPU6050 ready!");
  delay(500);

  while(!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println(F("SSD1306 allocation failed"));
    for(;;);
  }
  Serial.println("OLed ready!");
  delay(500);
  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(WHITE);

  mpu.setAccelerometerRange(MPU6050_RANGE_16_G);
  mpu.setGyroRange(MPU6050_RANGE_250_DEG);
  mpu.setFilterBandwidth(MPU6050_BAND_21_HZ);
  Serial.println("");
}


void loop() {
  digitalWrite(trigPin, LOW); // Clears the trigPin
  delayMicroseconds(2);
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10); // Sets the trigPin on HIGH state for 10 micro seconds
  digitalWrite(trigPin, LOW);
  
  duration = pulseIn(echoPin, HIGH); // Reads the echoPin, returns the sound wave travel time in microseconds
  distanceCm = duration * SOUND_SPEED/2; // Calculate the distance
  distanceInch = distanceCm * CM_TO_INCH; // Convert to inches

  sensors_event_t a, g, temp;
  mpu.getEvent(&a, &g, &temp);
  
  display.clearDisplay();
  display.setCursor(0, 0);
  display.print("Distance(cm): " + String(distanceCm));
  display.setCursor(0, 10);
  display.print("Distance(inch): " + String(distanceInch));
  display.setCursor(0, 25);
  display.print("Accel X: " + String(a.acceleration.x) + ", Y: " + String(a.acceleration.y) + ", Z: " + String(a.acceleration.z));
  display.setCursor(0, 45);
  display.print("Gyro X: " + String(g.gyro.x) + ", Y: " + String(g.gyro.y) + ", Z: " + String(g.gyro.z));
  display.display();
  delay(1000);
}