/* Creare un sistema di allarme.
Tramite tastierino numerico deve essere possibile inserire un codice di sblocco
e modificare il codice esistente. L’allarme dovrà poi scattare
quando ci si avvicina troppo ad un sensore di distanza,
la soglia deve essere programmata tramite un potenziometro.
*/
#include <Keypad.h>
#include <LiquidCrystal_I2C.h>
#define POT A0
#define BUZZ 13
#define TRIGGERPIN 12
#define ECHOPIN 11

const uint8_t ROWS = 4;
const uint8_t COLS = 4;
char keys[ROWS][COLS] = {
  { '1', '2', '3', 'A' },
  { '4', '5', '6', 'B' },
  { '7', '8', '9', 'C' },
  { '*', '0', '#', 'D' }
};

uint8_t colPins[COLS] = { 6,5,4,3 }; // Pins connected to C1, C2, C3, C4
uint8_t rowPins[ROWS] = { 10,9,8,7 }; // Pins connected to R1, R2, R3, R4

LiquidCrystal_I2C lcd(0x27,20,4);
Keypad keypad = Keypad(makeKeymap(keys), rowPins, colPins, ROWS, COLS);

String code = "";
String correctCode = "1234"; // Default code
float distance = 0;
char pressed;
bool alarmActive = true;

void setup()
{
  Serial.begin(9600);
  lcd.begin(20, 4);
  lcd.backlight();

  pinMode(TRIGGERPIN, OUTPUT);
  pinMode(ECHOPIN, INPUT);
  pinMode(BUZZ, OUTPUT);

  showMenu();
}

void loop()
{ 
  // Get pressed element
  pressed = keypad.getKey();

  if (pressed) {
  
    // Start selected
    if (pressed == '*') {
      lcd.clear();
      code = getCode();
        if (code == correctCode) {
          lcd.clear();
          lcd.print("Code Correct!");
          alarmActive = false;
          delay(2000);
        }
        else {
          lcd.clear();
          lcd.print("Code Incorrect!");
          alarmOn();
          delay(2000);
          lcd.clear();
        }
    showMenu();
    }
  
    // Reset selected
    if (pressed == '#') {
      lcd.clear();
      lcd.print("Set New Code: ");
      correctCode = getCode();
      lcd.clear();
      lcd.print("Code updated!");
      delay(2000);
      lcd.clear();

      showMenu();
    }
  }

  // Controlla la distanza
  distance = getDistance();
  int potDistance = map(analogRead(POT), 0, 1023, 1, 350);

  // Se l'allarme è attivo e qualcuno si avvicina troppo
  if (alarmActive && distance < potDistance) {
    lcd.clear();
    lcd.print("Alarm! Distance: ");
    lcd.setCursor(0, 1);
    lcd.print(distance);
    alarmOn();
  }
}

// Start Menu
void showMenu() {
  lcd.clear();
  lcd.home();
  lcd.print("Select option: ");
  lcd.setCursor(3, 2);
  lcd.print("*: Start");
  lcd.setCursor(3, 3);
  lcd.print("#: Reset Code");
}

// Prende input dal utente di 4 numeri
String getCode () {
  String inputCode = "";
  while (inputCode.length() < 4) {
    char key = keypad.getKey();
    if (key) {
      inputCode += key;
      lcd.setCursor(inputCode.length() - 1, 1);
      lcd.print(key);
    }
  }
  return inputCode;
}

// Calcolare la distanza dal sensore a ultrasuoni
float getDistance() {
  // Inizializzazione del sensore
  digitalWrite(TRIGGERPIN, LOW);
  delayMicroseconds(2);
  digitalWrite(TRIGGERPIN, HIGH);
  delayMicroseconds(10);
  digitalWrite(TRIGGERPIN, LOW);

  return pulseIn(ECHOPIN, HIGH) / 58;
}

// Attiva allarme
void alarmOn () {
  tone(BUZZ, 1000);
  delay(500);
  noTone(BUZZ);
}