#include <WiFi.h>
#include <PubSubClient.h>

#define led 18

const int PIN_ECHO = 17;
const int PIN_TRIG = 14;

// credenciais para acesso à rede e ao MQTT
const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqtt_server = "test.mosquitto.org";

WiFiClient WOKWI_client;
PubSubClient client(WOKWI_client);

void setup_wifi() {
  delay(10);
  // Inicia a conexão com a rede Wi-Fi
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void reconnect() {
  // Tenta reconectar ao MQTT broker
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    if (client.connect("WOKWI_client")) {
      Serial.println("connected");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void setup() {
  Serial.begin(115200);
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  pinMode(PIN_TRIG, OUTPUT);
  pinMode(PIN_ECHO, INPUT);
  pinMode(led, OUTPUT);
}

void envio_dist() {
  // Envia um pulso de 10 microsegundos para iniciar a medição
  digitalWrite(PIN_TRIG, LOW);
  delayMicroseconds(2);
  digitalWrite(PIN_TRIG, HIGH);
  delayMicroseconds(10);
  digitalWrite(PIN_TRIG, LOW);
  
  // Calcula o tempo do pulso
  long duration = pulseIn(PIN_ECHO, HIGH, 30000); // timeout de 30ms para evitar travamento

  if (duration == 0) {
    Serial.println("No echo detected");
    return; // Não continua se nenhum eco for detectado
  }
  
  // Calcula a distância em centímetros
  int distance = duration / 58.0;

  // Publica no tópico MQTT
  String presenca;

  if(distance < 270){
    presenca = "Alguem esta se aproximando";
    digitalWrite(led, HIGH);
  }
  else{
    presenca = "Nenhum objeto detectado";
    digitalWrite(led, LOW);
  }
  client.publish("presenca_c2", String(presenca).c_str());
  
  Serial.println(presenca);
  
  delay(2000); // Aguarda 2 segundos antes de fazer a próxima medição
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  envio_dist();
}