#include <WiFi.h>
#include <PubSubClient.h>

const char* ssid = "Wokwi-GUEST";  
const char* password = "";         
const char* mqtt_server = "test.mosquitto.org"; 

WiFiClient espClient;
PubSubClient client(espClient);

const int ledBarPins[] = {21, 19, 18, 5, 17, 16, 4, 0, 2, 15}; 
const int numLeds = 10;  
const int buzzer = 14;

void setup() {
  Serial.begin(115200);

  for (int i = 0; i < numLeds; i++) {
    pinMode(ledBarPins[i], OUTPUT);
  }
  pinMode(buzzer, OUTPUT); 

  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.println("Conectando ao WiFi...");
  }
  Serial.println("Conectado ao WiFi");

  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);

  reconnect();
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();
}

void callback(char* topic, byte* payload, unsigned int length) {
  String message;
  for (int i = 0; i < length; i++) {
    message += (char)payload[i];
  }

  float humidity = message.toFloat();  
  Serial.print("Umidade recebida: ");
  Serial.println(humidity);

  int ledsToLight = map(humidity, 0, 100, 0, numLeds);

  for (int i = 0; i < numLeds; i++) {
    if (i < ledsToLight) {
      digitalWrite(ledBarPins[i], HIGH);
    } else {
      digitalWrite(ledBarPins[i], LOW);
    }
  }

  if (humidity >= 80) {
    tone(buzzer, 1000);  
  } else {
    noTone(buzzer);  
  }
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Tentando conectar ao MQTT...");
    if (client.connect("ESP32Client2")) {
      Serial.println("Conectado");
      client.subscribe("esp32/umidade"); 
    } else {
      Serial.print("Falha, rc=");
      Serial.print(client.state());
      delay(5000);
    }
  }
}