#include <MD_Parola.h>
#include <MD_MAX72xx.h>
#include <SPI.h>
#include <DHT.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>

// set to 1 if we are implementing the user interface pot, switch, etc
#define USE_UI_CONTROL 0

#if USE_UI_CONTROL
#include <MD_UISwitch.h>
#endif

// Turn on debug statement to the serial output
#define DEBUG 0

#if DEBUG
#define PRINT(s, x) { Serial.print(F(s)); Serial.print(x); }
#define PRINTS(x) Serial.print(F(x))
#define PRINTX(x) Serial.println(x, HEX)
#else
#define PRINT(s, x)
#define PRINTS(x)
#define PRINTX(x)
#endif

// Define the number of devices we have in the chain and the hardware interface
#define HARDWARE_TYPE MD_MAX72XX::PAROLA_HW
#define MAX_DEVICES 11
#define CLK_PIN 13
#define DATA_PIN 11
#define CS_PIN 10

// HARDWARE SPI
MD_Parola P = MD_Parola(HARDWARE_TYPE, CS_PIN, MAX_DEVICES);

//Scrolin parameter
#if USE_UI_CONTROL
const uint8_t SPEED_IN = A5;
const uint8_t DIRECTION_SET = 8;
const uint8_t INVERT_SET = 9;

const uint8_t SPEED_DEADBAND = 5;
#endif //USE_UI_CONTROL

uint8_t scrollspeed = 25;
textEffect_t scrollEffect = PA_SCROLL_LEFT;
textPosition_t scrollAlign = PA_LEFT;
uint16_t scrollPause = 0; // Changed to 0 for continuous scrolling

// Global message buffers shared by serial and scrolling functions
#define BUF_SIZE 100
char curMessage[BUF_SIZE] = { "DEMO PENGABDIAN KEPADA MASYARAKAT" };
char newMessage[BUF_SIZE] = { "" };
bool newMessageAvailable = true;

#if USE_UI_CONTROL
MD_UISwitch_Digital uiDirection(DIRECTION_SET);
MD_UISwitch_Digital uiInvert(INVERT_SET);

void doUI(void)
{
  // set the speed if the has changed
  {
    int16_t speed = map(analogRead(SPEED_IN), 0, 1023, 10, 150);

    if ((speed >= ((int16_t)P.getSpeed() + SPEED_DEADBAND)) ||
        (speed <= ((int16_t)P.getSpeed() - SPEED_DEADBAND)))
    {
      P.setSpeed(speed);
      scrollspeed = speed;
      PRINT("\nchanged speed to ", P.getSpeed());
    }
  }

  if (uiDirection.read() == MD_UISwitch::KEY_PRESS) // SCROLL DIRECTION
  {
    PRINTS("\nchanging scroll direction");
    scrollEffect = (scrollEffect == PA_SCROLL_LEFT ? PA_SCROLL_RIGHT : PA_SCROLL_LEFT);
    P.setTextEffect(scrollEffect, scrollEffect);
    P.displayClear();
    P.displayReset();
  }
  
  if (uiInvert.read() == MD_UISwitch::KEY_PRESS) // INVERT MODE
  {
    PRINTS("\nChanging invert mode");
    P.setInvert(!P.getInvert());
  }
}
#endif // USE_UI_CONTROL

void readSerial(void)
{
  static char *cp = newMessage;

  while (Serial.available())
  {
    *cp = (char)Serial.read();
    if ((*cp == '\n') || (cp - newMessage >= BUF_SIZE - 2))
    {
      *cp = '\0';
      cp = newMessage;
      newMessageAvailable = true;
    }
    else
      cp++;
  }
}

#define DHTPIN 2
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE);

// constants for LCD
LiquidCrystal_I2C lcd(0x27, 16, 2);

//constants for relay and LED
const int relayPin = 7;
const int ledPin = 8;

void setup()
{
  Serial.begin(57600);
  Serial.print("\n[Parola Scrolling Display]\nType a message for the scrolling display\nEnd message line with a newline");

#if USE_UI_CONTROL
  uiDirection.begin();
  uiInvert.begin();
  pinMode(SPEED_IN, INPUT);
  doUI();
#endif // USE_UI_CONTROL

  P.begin();
  P.displayText(curMessage, scrollAlign, scrollspeed, scrollPause, scrollEffect, scrollEffect);
  P.displayReset(); // Reset display to start animation

  Serial.begin(9600);
  dht.begin();
  lcd.begin(16, 2);
  pinMode(relayPin, OUTPUT);
  pinMode(ledPin, OUTPUT);
}

void loop() {
#if USE_UI_CONTROL
  doUI();
#endif // USE_UI_CONTROL

  // Always reset the animation to create continuous loop
  if (P.displayAnimate())
  {
    if (newMessageAvailable)
    {
      strcpy(curMessage, newMessage);
      newMessageAvailable = false;
      P.displayReset();
    }
    else
    {
      // Reset animation even when no new message to create continuous loop
      P.displayReset();
    }
  }
  
  readSerial();

  // Baca sensor dan update LCD setiap 2 detik (non-blocking)
  static unsigned long lastSensorRead = 0;
  unsigned long currentMillis = millis();
  
  if (currentMillis - lastSensorRead >= 2000) {
    lastSensorRead = currentMillis;
    
    // membaca suhu dan kelembaban
    float humidity = dht.readHumidity();
    float temperature = dht.readTemperature();

    // memeriksa apakah pembacaan valid
    if (isnan(humidity) || isnan(temperature)) {
      Serial.println("Gagal membaca sensor DHT22");
      lcd.clear();
      lcd.setCursor(0, 0);
      lcd.print("Error Sensor DHT");
      return;
    }

    // menampilkan suhu/kelembaban pada LCD
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("Suhu: ");
    lcd.print(temperature, 1);
    lcd.print(" C");
    lcd.setCursor(0, 1);
    lcd.print("Lembab: ");
    lcd.print(humidity, 1);
    lcd.print(" %");
    
    // mengendalikan relay dan LED berdasarkan suhu
    if (temperature > 20) {
      digitalWrite(relayPin, HIGH);
      digitalWrite(ledPin, HIGH);
    } else {
      digitalWrite(relayPin, LOW);
      digitalWrite(ledPin, LOW);
    }
  }
}