#include <WiFi.h>
#include <WiFiClientSecure.h>       // Librería para manejar SSL/TLS
#include <PubSubClient.h>
#include "DHT.h"

// Configuración de WiFi
const char* ssid = "Wokwi-GUEST";
const char* password = "";

// Configuración del broker MQTT HiveMQ
const char* mqtt_server = "502f55fd147b450f8755676ed322337b.s1.eu.hivemq.cloud";
const int mqtt_port = 8883;
const char* mqtt_user = "hivemq.webclient.1730159879132";           // Coloca tu nombre de usuario de HiveMQ Cloud
const char* mqtt_password = "XH$!<#OwNDqxgh72Ss39";       // Coloca tu contraseña de HiveMQ Cloud

const char* mqtt_topic_temp = "Temperatura";
const char* mqtt_topic_hum = "Humedad";

// Cliente MQTT seguro
WiFiClientSecure espClientSecure;
PubSubClient client(espClientSecure);

// Configuración del sensor DHT22
#define DHTPIN 12
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE);

void setup_wifi() {
  delay(10);
  Serial.print("Conectando a ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.print(".");
  }
  Serial.println("Conectado a la red WiFi");
  Serial.println("Dirección IP: ");
  Serial.println(WiFi.localIP());
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Intentando conectar al broker MQTT...");
    if (client.connect("ESP32Client", mqtt_user, mqtt_password)) {
      Serial.print(client.state());
      Serial.println("Conectado al broker MQTT");
    } else {
      Serial.print("Fallo, rc=");
      Serial.print(client.state());
      Serial.println(" Intentando de nuevo en 5 segundos");
      delay(5000);
    }
  }
}

void setup() {
  Serial.begin(115200);
  dht.begin();
  setup_wifi();

  // Configuración de conexión segura
  espClientSecure.setInsecure(); // Permitir conexión sin verificación de certificado (opcional)
  
  client.setServer(mqtt_server, mqtt_port);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  float temperatura = dht.readTemperature();
  float humedad = dht.readHumidity();

  if (isnan(temperatura) || isnan(humedad)) {
    Serial.println("Error al leer el sensor DHT22");
    return;
  }

  String tempStr = String(temperatura);
  String humStr = String(humedad);

  client.publish(mqtt_topic_temp, tempStr.c_str());
  client.publish(mqtt_topic_hum, humStr.c_str());

  Serial.print("Temperatura: ");
  Serial.print(temperatura);
  Serial.println(" °C");
  
  Serial.print("Humedad: ");
  Serial.print(humedad);
  Serial.println(" %");

  delay(5000);
}