#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <DHT.h> 

#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
#define OLED_RESET -1

#define DHTPIN 2 // Pin für den DHT22-Sensor
#define DHTTYPE DHT22 // DHT22 als Sensortyp definiert
#define LED_PIN 8 // Pin für die LED

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);
DHT dht(DHTPIN, DHTTYPE);

// Variablen zur Speicherung der letzten Messwerte
float lastTemperature = NAN;
float lastHumidity = NAN;

void setup() {
  Serial.begin(9600);

  // Initialisiere das OLED-Display mit I2C-Adresse 0x3C
  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) { // 0x3C ist die Standardadresse
        Serial.println(F("SSD1306 allocation failed"));
        for(;;); // Stopt das Programm, falls Display nicht initiallisiert wird
  }

  display.display();
  delay(2000); // Pause für zwei Sekunden

  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);
  
  // Initiallisiere den DHT22-Sensor
  dht.begin();

  // Setze den LED_PIN als Ausgang
  pinMode(LED_PIN, OUTPUT);
}

void loop() {
    // Lese Temperatur und Luftfeuchtigkeit vom DHT22-Sensor
    float temperature = dht.readTemperature();
    float humidity = dht.readHumidity();

    // Überprüfe, ob die Sensorwerte gültig sind
    if (isnan(temperature) || isnan(humidity)) {
        Serial.println(F("Error reading from DHT22 sensor!"));
        display.clearDisplay();
        display.setCursor(0, 0);
        display.print("Sensor Error!");
        display.display();
    } else {
        // Überprüft, ob sich die Werte geändert haben
        if (temperature != lastTemperature || humidity != lastHumidity) {
          // Lösche das Display und zeige die Sensorwerte an
          display.clearDisplay();
          display.setCursor(0, 0);
          display.print("Temperature: ");
          display.print(temperature);
          display.println(" C");

          display.setCursor(0, 16);
          display.print("Humidity: ");
          display.print(humidity);
          display.println(" %");

          display.display(); // Aktualisiere das Display

          // Lässt die LED blinken, um anzuzeigen, dass neue Daten angezeigt werden
          digitalWrite(LED_PIN, HIGH);  // LED an
          delay(100);                   // Warte 100 ms
          digitalWrite(LED_PIN, LOW);   // LED aus

          // Speichere die aktuellen Werte als letzte Messweerte
          lastTemperature = temperature;
          lastHumidity = humidity;
      }
    }

  delay(2000); // Warte 2 Sekunden vor der nächsten Messung
}