#include <WiFi.h>
#include <PubSubClient.h>
#include <DHTesp.h>
#include <ArduinoJson.h>

// Configurações de pinos
const int DHT_PIN = 15;
const int TRIGGER_PIN = 5;
const int ECHO_PIN = 18;
const int BUZZER_PIN = 19;

DHTesp dht;

// Configurações Wi-Fi e MQTT
const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqtt_server = "test.mosquitto.org";

//const char* mqtt_server = "broker.hivemq.com";

WiFiClient espClient;
PubSubClient client(espClient);
unsigned long lastMsg = 0;
const long interval = 5000; // Intervalo de 3 minutos (em milissegundos)

void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Conectando-se a ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi conectada");
  Serial.println("Endereco IP: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Mensagem recebida [");
  Serial.print(topic);
  Serial.print("] ");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }
  Serial.println();
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Tentando conexao MQTT...");
    String clientId = "ESP32Client-";
    clientId += String(random(0xffff), HEX);
    if (client.connect(clientId.c_str())) {
      Serial.println("Conectado");
      client.publish("/senai/Publish", "Bem vindo!");
      client.subscribe("/senai/Subscribe");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" tentando novamente em 5 segundos");
      delay(5000);
    }
  }
}

void setup() {
  pinMode(TRIGGER_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);
  pinMode(BUZZER_PIN, OUTPUT);
  Serial.begin(115200);
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
  dht.setup(DHT_PIN, DHTesp::DHT22);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  unsigned long now = millis();
  if (now - lastMsg > interval) {  // 3 minutos de intervalo
    lastMsg = now;

    // Leitura da temperatura e umidade
    TempAndHumidity data = dht.getTempAndHumidity();
    float temp = data.temperature;
    float hum = data.humidity;

    // Medição da distância usando o sensor ultrassônico
    digitalWrite(TRIGGER_PIN, LOW);
    delayMicroseconds(2);
    digitalWrite(TRIGGER_PIN, HIGH);
    delayMicroseconds(10);
    digitalWrite(TRIGGER_PIN, LOW);

    long duration = pulseIn(ECHO_PIN, HIGH);
    float distance = (duration * 0.034) / 2;

    // Cria o objeto JSON
    StaticJsonDocument<200> doc;
    doc["temperatura"] = temp;
    doc["umidade"] = hum;
    doc["distancia"] = distance;

    // Serializa o JSON para um buffer
    char jsonBuffer[256];
    serializeJson(doc, jsonBuffer);

    // Publica o JSON no tópico MQTT
    client.publish("/senai/sensorData", jsonBuffer);
    Serial.print("Dados enviados: ");
    Serial.println(jsonBuffer);

    // Controle do buzzer com base em limiares
    if (distance < 20.0 || temp > 30.0 || hum > 70.0) {
      digitalWrite(BUZZER_PIN, HIGH);
      tone(19, 262, 250);  // Toca um tom de 262Hz por 0,250 segundos
    } else {
      digitalWrite(BUZZER_PIN, LOW);
    }
  }
}