#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>
#include <OneWire.h>
#include <DallasTemperature.h>

// Configuración WiFi y MQTT
const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqtt_server = "test.mosquitto.org"; // MQTT broker

WiFiClient espClient;
PubSubClient client(espClient);

// Pines y configuración de sensores
#define DHTPIN 21        // Pin GPIO para el DHT22
#define DHTTYPE DHT22     // Tipo de sensor DHT22
DHT dht(DHTPIN, DHTTYPE);

#define ONE_WIRE_BUS 18   // Pin GPIO para el DS18B20
OneWire oneWire(ONE_WIRE_BUS);
DallasTemperature ds18b20(&oneWire);

unsigned long lastSend = 0; // Para controlar el intervalo de envío

void setup() {
  Serial.begin(115200);
  setup_wifi();
  client.setServer(mqtt_server, 1883);

  dht.begin();         // Inicializar el sensor DHT22
  ds18b20.begin();     // Inicializar el sensor DS18B20
}

void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void reconnect() {
  // Mantener la conexión con el broker MQTT
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    if (client.connect("ESPClient")) {
      Serial.println("connected");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds"); 
      delay(5000);
    }
  }
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  // Enviar datos cada 10 segundos
  unsigned long now = millis();
  if (now - lastSend > 10000) {
    lastSend = now;

    // Leer temperatura y humedad del DHT22
    float h = dht.readHumidity();
    float t1 = dht.readTemperature();

    // Comprobar si la lectura es válida
    if (isnan(h) || isnan(t1)) {
      Serial.println("Failed to read from DHT sensor!");
    } else {
      Serial.print("Humidity: ");
      Serial.print(h);
      Serial.print(" %\t");
      Serial.print("Temperature from DHT22: ");
      Serial.print(t1);
      Serial.println(" *C");

      // Enviar datos de DHT22 por MQTT
      char tempStr[8];
      char humStr[8];
      dtostrf(t1, 1, 2, tempStr);
      dtostrf(h, 1, 2, humStr);
      client.publish("/Ulabtemp/t1", tempStr); // Topic de temperatura del DHT22
      client.publish("/Ulabtemp/h", humStr);  // Topic de humedad del DHT22
    }

    // Leer temperatura del DS18B20
    ds18b20.requestTemperatures();
    float t2 = ds18b20.getTempCByIndex(0);

    // Comprobar si la lectura es válida
    if (t2 == DEVICE_DISCONNECTED_C) {
      Serial.println("Failed to read from DS18B20 sensor!");
    } else {
      Serial.print("Temperature from DS18B20: ");
      Serial.print(t2);
      Serial.println(" *C");

      // Enviar datos de DS18B20 por MQTT
      char tempDSStr[8];
      dtostrf(t2, 1, 2, tempDSStr);
      client.publish("/Ulabtemp/t2", tempDSStr); // Topic de temperatura del DS18B20
    }
  }

  delay(100);
}