#include <WiFi.h>
#include <PubSubClient.h>

int numLEDs = 4;
int pinLED[] = {16, 17, 18, 19};  // Sửa dấu chấm thành dấu phẩy

const char * MQTTServer = "broker.emqx.io";
const char * MQTT_Topic = "VLUTE/LED/status";
const char * mqtt_username = "huuthocse";
const char * mqtt_password = "12345678";
const char * MQTT_ID = "db43082a-2142-4ef6-b278-d20b0faeeb18";
int Port = 1883;

WiFiClient espClient;
PubSubClient client(espClient);

void WIFIConnect() {
  Serial.println("Connecting to SSID: Wokwi-GUEST");
  WiFi.begin("Wokwi-GUEST", "");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("WiFi connected");
  Serial.print(", IP address: ");
  Serial.println(WiFi.localIP());
}

void MQTT_Reconnect() {
  while (!client.connected()) {
    if (client.connect(MQTT_ID, mqtt_username, mqtt_password)) {
      Serial.println("Connected to MQTT Broker!");
      client.subscribe(MQTT_Topic);
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void callback(char* topic, byte* message, unsigned int length) {
  Serial.print("Message arrived on topic: ");
  Serial.println(topic);
  Serial.print("Message: ");
  String stMessage;

  for (int i = 0; i < length; i++) {
    Serial.print((char)message[i]);
    stMessage += (char)message[i];
  }
  Serial.println();

  // Xử lý thông điệp để bật/tắt từng LED
  if (stMessage.startsWith("led")) {
    int ledIndex = stMessage.substring(3, 4).toInt() - 1; // Lấy số LED từ thông điệp (vd: "led1 on")

    if (ledIndex >= 0 && ledIndex < numLEDs) {
      if (stMessage.endsWith("on")) {
        digitalWrite(pinLED[ledIndex], HIGH);
      } else if (stMessage.endsWith("off")) {
        digitalWrite(pinLED[ledIndex], LOW);
      }
    }
  }
}

void setup() {
  Serial.begin(115200);

  WIFIConnect();
  client.setServer(MQTTServer, Port);
  client.setCallback(callback);

  for (int i = 0; i < numLEDs; i++) {
    pinMode(pinLED[i], OUTPUT);
  }
}

void loop() {
  delay(10);
  if (!client.connected()) {
    MQTT_Reconnect();
  }
  client.loop();
}