#include <WiFi.h>
#include <MQTT.h>
#include "DHT.h"

const char ssid[] = "Wokwi-GUEST";
const char pass[] = "";

WiFiClient net;
MQTTClient client;

#define DHT22Pin 5

#define ledRed 27
#define ledBlue 26

DHT dht(DHT22Pin, DHT22);

unsigned long lastMillis = 0;

void connect(){
  // Menghubungkan ke WiFi
  Serial.print("Cek WiFi");
  while(WiFi.status() != WL_CONNECTED){
    Serial.print(".");
    delay(1000);
  }
  Serial.println("");
  Serial.println("Sukses Terhubung ke WiFi");

  // Menghubungkan ke Broker
  Serial.print("Cek Broker");
  while(!client.connect("")){ // Client ID boleh dikosongkan
    Serial.print(".");
    delay(1000);
  }
  Serial.println("");
  Serial.println("Sukses Terhubung ke Server");
  
  client.subscribe("labskite/iot/#", 1); // subcribe dengan QoS 1
}

void reconnect() {
  Serial.print("Menghubungkan ke Broker");
  while(!client.connect("")){ // Client ID tidak boleh sama
    Serial.print(".");
    delay(1000);
  }
  Serial.println("");
  Serial.println("Berhasil Terhubung ke Server");
  
  client.subscribe("labskite/iot/#", 1); // subcribe dengan QoS 1
}

void subscribeData(String &topic, String &data){
  Serial.print("Topic: ");
  Serial.println(topic);
  Serial.print("Data: ");
  Serial.println(data);

  if(topic == "labskite/iot/led1"){  
    digitalWrite(ledRed, data.toInt());   //control led 1
    client.publish("labskite/iot/led1/status", data, true, 1);
  }

  if(topic == "labskite/iot/led2"){
    digitalWrite(ledBlue, data.toInt());   //control led 2
    client.publish("labskite/iot/led2/status", data, true, 1);   
  }

  if(topic == "labskite/iot/onsemua"){  
    digitalWrite(ledRed, HIGH);
    digitalWrite(ledBlue, HIGH);
  }

  if(topic == "labskite/iot/offsemua"){
    digitalWrite(ledRed, LOW);
    digitalWrite(ledBlue, LOW);
  }

}

void publish(){
  float hum = dht.readHumidity();
  float temp = dht.readTemperature();
  Serial.print("Temperature : ");
  Serial.print(temp);
  Serial.print(" C ");

  Serial.print("Humidity : ");
  Serial.print(hum);
  Serial.println(" % ");

  client.publish("labskite/iot/dht/temp", String(temp), true, 1); // publish variabel temperatue ke topic labskite/iot/dht/temp dengan QoS 1
  client.publish("labskite/iot/dht/humi", String(hum), true, 1); // publish variabel humidity ke topic labskite/iot/dht/humi dengan QoS 1
}

void setup() {
  Serial.begin(115200);
  pinMode(ledRed,OUTPUT); 
  pinMode(ledBlue,OUTPUT);
  dht.begin();

  Serial.begin(9600);
  WiFi.begin(ssid, pass);
  client.begin("broker.emqx.io", net);
  client.onMessage(subscribeData); 
  connect();
}

void loop() {
   if (!client.connected()) { // If client is not connected
    reconnect(); // Try to reconnect
  }
   client.loop();
   
// publish a message roughly every second.
 if (millis() - lastMillis > 1000) {
    lastMillis = millis();
    publish();
  }
  delay(10);
}