#include <WiFi.h>
#include "PubSubClient.h"
#include <ArduinoJson.h>

const char * MQTTServer = "broker.emqx.io";
const char * MQTT_Topic = "conghoa";

// Tạo ID ngẫu nhiên tại: https://www.guidgen.com/
const char * MQTT_ID = "conghoa";
int Port = 1883;

WiFiClient espClient;
PubSubClient client(espClient);

void WIFIConnect() {
  Serial.println("Connecting to SSID: Wokwi-GUEST");
  WiFi.begin("Wokwi-GUEST", "");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("WiFi connected");
  Serial.print(", IP address: ");
  Serial.println(WiFi.localIP());
}

void MQTT_Reconnect() {
  while (!client.connected()) {
    if (client.connect(MQTT_ID)) {
      Serial.print("MQTT Topic: ");
      Serial.print(MQTT_Topic);
      Serial.print(" connected");
      client.subscribe(MQTT_Topic);
      Serial.println("");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void callback(char* topic, byte* message, unsigned int length) {
  Serial.print("Message arrived on topic: ");
  Serial.println(topic);

  // Chuyển đổi dữ liệu thành chuỗi
  String jsonMessage;
  for (int i = 0; i < length; i++) {
    jsonMessage += (char)message[i];
  }
  Serial.println("Received JSON message: " + jsonMessage);

  // Phân tích cú pháp JSON
  StaticJsonDocument<200> doc;
  DeserializationError error = deserializeJson(doc, jsonMessage);
  
  if (error) {
    Serial.print("JSON deserialization failed: ");
    Serial.println(error.c_str());
    return;
  }else{
    client.publish("danhan", String("Đã nhận").c_str());
  }

  // Truy xuất các giá trị từ JSON
  int red = doc["red"];  // Giá trị của "red"
  int green = doc["green"];  // Giá trị của "green"
  int yellow = doc["yellow"];  // Giá trị của "yellow"

  // Điều khiển LED
  digitalWrite(16, HIGH);
  delay(red);
  digitalWrite(16, LOW);
  digitalWrite(17, HIGH);
  delay(yellow);
  digitalWrite(17, LOW);
  digitalWrite(18, HIGH);
  delay(green);
  digitalWrite(18, LOW);
}

void setup() {
  Serial.begin(115200);

  WIFIConnect();
  client.setServer(MQTTServer, Port);
  client.setCallback(callback);
  // Khai báo chân đèn
  pinMode(16, OUTPUT);
  pinMode(17, OUTPUT);
  pinMode(18, OUTPUT);
}

void loop() {
  delay(10);
  if (!client.connected()) {
    MQTT_Reconnect();
  }
  client.loop();
}