#include <WiFi.h>
#include "PubSubClient.h"
#include <ArduinoJson.h>
#include <Keypad.h>

const char * MQTTServer = "broker.hivemq.com";
const char * MQTT_Topic = "conghoa";

// Tạo ID ngẫu nhiên tại: https://www.guidgen.com/
const char * MQTT_ID = "conghoa";
int Port = 1883;

WiFiClient espClient;
PubSubClient client(espClient);

// Cấu hình keypad
const uint8_t ROWS = 4;
const uint8_t COLS = 4;
char keys[ROWS][COLS] = {
  { '1', '2', '3', 'A' },
  { '4', '5', '6', 'B' },
  { '7', '8', '9', 'C' },
  { '*', '0', '#', 'D' }
};
uint8_t colPins[COLS] = { 19, 18, 5, 17 };
uint8_t rowPins[ROWS] = { 25, 26, 27, 14 };

Keypad keypad = Keypad(makeKeymap(keys), rowPins, colPins, ROWS, COLS);

void WIFIConnect() {
  Serial.println("Connecting to SSID: Wokwi-GUEST");
  WiFi.begin("Wokwi-GUEST", "");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("WiFi connected");
  Serial.print(", IP address: ");
  Serial.println(WiFi.localIP());
}

void MQTT_Reconnect() {
  while (!client.connected()) {
    if (client.connect(MQTT_ID)) {
      Serial.print("MQTT Topic: ");
      Serial.print(MQTT_Topic);
      Serial.print(" connected");
      client.subscribe(MQTT_Topic);
      Serial.println("");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void callback(char* topic, byte* message, unsigned int length) {
  Serial.print("Message arrived on topic: ");
  Serial.println(topic);
  Serial.print("Message: ");
  String stMessage;

   for (int i = 0; i < length; i++) {
    Serial.print((char)message[i]);
    stMessage += (char)message[i];
  }
  Serial.println();
  if (stMessage == "1") {
    tone(16, 262, 250); // Plays 262Hz tone for 0.250 seconds
    delay(1000);
    noTone(16);
  }
  else if (stMessage == "3") {
    for (int i = 0; i < 3; i++) {  // Lặp lại 3 lần
      tone(16, 262, 250);  // Phát âm 262Hz trong 250ms
      delay(300);          // Đợi thêm 50ms sau khi phát âm
      noTone(16);          // Tắt âm trước khi phát lần tiếp theo
    }
  }
}

String pass = "";

void guiMK() {
  // Đọc keypad và in ra màn hình
  char key = keypad.getKey();

  if (key != '\0' && key != '#') {  // Kiểm tra nếu key không phải là ký tự rỗng và không phải là '#'
    pass += key;  // Thêm key vào mật khẩu
    return;
  }

  if (key == '#') {  // Nếu phím là '#', gửi mật khẩu
    // Tạo chuỗi JSON để gửi
    String jsonData = String("{\"pass\":\"") + pass + String("\"}");

    // Gửi dữ liệu qua MQTT
    client.publish("pass", jsonData.c_str()); // name of topic and data with type is json
    Serial.println("Dữ liệu đã được gửi: " + jsonData);

    // Đặt lại mật khẩu sau khi gửi
    pass = "";
  }
}

void setup() {
  Serial.begin(115200);
  pinMode(16, OUTPUT);

  WIFIConnect();
  client.setServer(MQTTServer, Port);
  client.setCallback(callback);
}

void loop() {
  delay(10);
  if (!client.connected()) {
    MQTT_Reconnect();
  }
  client.loop();

  guiMK();
}