#include <DHT.h>
#include <WiFi.h>
#include "PubSubClient.h"

const char* MQTTServer = "broker.emqx.io";
const char* MQTT_Topic = "nhietdodoam";

#define DHTPIN 15      
#define DHTTYPE DHT22 

WiFiClient espClient;
PubSubClient client(espClient);

// Tạo ID ngẫu nhiên tại: https://www.guidgen.com/
const char* MQTT_ID = "a7413a9c-4843-489b-8c53-4ea253e17f02";
int Port = 1883;

DHT dht(DHTPIN, DHTTYPE);

void WIFIConnect() {
  Serial.println("Connecting to SSID: Wokwi-GUEST");
  WiFi.begin("Wokwi-GUEST", "");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("WiFi connected");
  Serial.print(", IP address: ");
  Serial.println(WiFi.localIP());
}

void MQTT_Reconnect() {
  while (!client.connected()) {
    if (client.connect(MQTT_ID)) {
      Serial.print("Connected to MQTT, Topic: ");
      Serial.println(MQTT_Topic);
    } else {
      Serial.print("Failed to connect, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }
  Serial.println();
}


void setup() {
  Serial.begin(115200);
  dht.begin();  // Khởi tạo cảm biến DHT
  
  WIFIConnect();
  client.setServer(MQTTServer, Port);
}

void loop() {
  if (!client.connected()) {
    MQTT_Reconnect();
  }
  client.loop();

  // Đọc nhiệt độ và độ ẩm từ cảm biến
  float h = dht.readHumidity();
  float t = dht.readTemperature();
  
  // Kiểm tra xem có đọc được dữ liệu từ cảm biến không
  if (isnan(t) || isnan(h)) {
    Serial.println("Failed to read from DHT sensor!");
    return;
  }

  // Tạo chuỗi JSON để gửi qua MQTT
  String data_send = "{\"temp_value\":\"" + String(t) + "\",\"press_value\":\"" + String(h) + "\"}";

  // Gửi dữ liệu JSON qua MQTT
  client.publish(MQTT_Topic, data_send.c_str());

  // In dữ liệu ra Serial để kiểm tra
  Serial.print("Temperature: ");
  Serial.print(t);
  Serial.print(" °C ");
  Serial.print("Humidity: ");
  Serial.print(h);
  Serial.println(" %");
  
  Serial.println("Data sent to MQTT: " + data_send);

  delay(2000); // Đọc và gửi dữ liệu mỗi 2 giây
}