#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>

WiFiClient espClient;
PubSubClient client(espClient);

#define DHTPIN 21
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE);

// WiFi
const char *ssid = "Wokwi-GUEST";
const char *password = ""; 
int Port = 1883;

// MQTT Broker
const char *MQTTServer = "broker.emqx.io";
const char *MQTT_Topic = "VLUTE/DHT22";

// Tạo ID ngẫu nhiên tại: https://www.guidgen.com/
const char *MQTT_ID = "91bdc853-79bb-433a-8121-98b2460e183a";

void MQTT_Reconnect() {
  while (!client.connected()) {
    if (client.connect(MQTT_ID)) {
      Serial.println("Connected to MQTT Broker!");
      client.subscribe(MQTT_Topic);
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void WIFIConnect() {
  Serial.println("Connecting to SSID: Wokwi-GUEST");
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("WiFi connected");
  Serial.print(", IP address: ");
  Serial.println(WiFi.localIP());
}

void setup() {
  Serial.begin(115200);
  dht.begin();

  WIFIConnect();
  client.setServer(MQTTServer, Port);
}

void loop() {
  delay(2000);  // Cập nhật dữ liệu mỗi 2 giây

  if (!client.connected()) {
    MQTT_Reconnect();
  }
  client.loop();

  // Đọc nhiệt độ và độ ẩm từ cảm biến
  float temperature = dht.readTemperature();
  float humidity = dht.readHumidity();

  if (isnan(temperature) || isnan(humidity)) {
    Serial.println("Failed to read from DHT sensor!");
    return;
  }

  // Tạo thông điệp JSON
  char message[50];
  snprintf(message, 50, "{\"temperature\": %.2f, \"humidity\": %.2f}", temperature, humidity);

  // Gửi thông điệp lên broker
  client.publish(MQTT_Topic, message);
  Serial.print("Message sent: ");
  Serial.println(message);
}