#include <WiFi.h>
#include <WiFiClientSecure.h>
#include <LiquidCrystal_I2C.h>
#include <DHT.h>
#include <PubSubClient.h>

const char* ssid = "Wokwi-GUEST";
const char* password = "";

const char* mqtt_server = "4a9f1387033a402797662d8ba77823a1.s1.eu.hivemq.cloud";
const int mqtt_port = 8883;
const char* mqtt_username = "Elizabeth";
const char* mqtt_password = "Jo2005hana.";

// Configuración de LCD
#define LCD_ADDRESS 0x27
#define LCD_COLUMNS 20
#define LCD_ROWS 4
LiquidCrystal_I2C lcd(LCD_ADDRESS, LCD_COLUMNS, LCD_ROWS);

// Tópicos de MQTT
const char* CONTROL_BUZZER = "Alarma/Buzzer";
const char* CONTROL_SERVOMOTOR = "CajaFuerte";
const char* TOPICO_MQ2 = "Sensores/Gas";
const char* TOPICO_LUZ = "Sensores/Luz";
const char* TOPICO_TEMPHUM = "Sensores/TempHum";

// Pines Actuadores
const int ledBlancoPin = 12;     // Led Blanco para indicar falta de luz
const int ledRojoPin = 13;       // Led Rojo para alta temperatura
const int ledAzulPin = 14;       // Led Azul para baja temperatura
const int buzzerPin = 25;        // Buzzer para alerta de gas
const int servoPin = 26;         // Servomotor

// Pines de sensores
const int ldrPin = 2;            // Sensor de Luz 
const int dhtPin = 15;           // Sensor de Temp y Humedad
const int mq2Pin = 4;            // Sensor de gas MQ2

// Configuración de cliente WiFi y MQTT
WiFiClientSecure espClient;
PubSubClient client(espClient);
DHT dht(dhtPin, DHT22);  // Configuración del sensor DHT22

// Certificado raíz para conexión segura
static const char* root_ca PROGMEM = R"EOF(
-----BEGIN CERTIFICATE-----
MIIFazCCA1OgAwIBAgIRAIIQz7DSQONZRGPgu2OCiwAwDQYJKoZIhvcNAQELBQAw
TzELMAkGA1UEBhMCVVMxKTAnBgNVBAoTIEludGVybmV0IFNlY3VyaXR5IFJlc2Vh
cmNoIEdyb3VwMRUwEwYDVQQDEwxJU1JHIFJvb3QgWDEwHhcNMTUwNjA0MTEwNDM4
WhcNMzUwNjA0MTEwNDM4WjBPMQswCQYDVQQGEwJVUzEpMCcGA1UEChMgSW50ZXJu
ZXQgU2VjdXJpdHkgUmVzZWFyY2ggR3JvdXAxFTATBgNVBAMTDElTUkcgUm9vdCBY
MTCCAiIwDQYJKoZIhvcNAQEBBQADggIPADCCAgoCggIBAK3oJHP0FDfzm54rVygc
h77ct984kIxuPOZXoHj3dcKi/vVqbvYATyjb3miGbESTtrFj/RQSa78f0uoxmyF+
0TM8ukj13Xnfs7j/EvEhmkvBioZxaUpmZmyPfjxwv60pIgbz5MDmgK7iS4+3mX6U
A5/TR5d8mUgjU+g4rk8Kb4Mu0UlXjIB0ttov0DiNewNwIRt18jA8+o+u3dpjq+sW
T8KOEUt+zwvo/7V3LvSye0rgTBIlDHCNAymg4VMk7BPZ7hm/ELNKjD+Jo2FR3qyH
B5T0Y3HsLuJvW5iB4YlcNHlsdu87kGJ55tukmi8mxdAQ4Q7e2RCOFvu396j3x+UC
B5iPNgiV5+I3lg02dZ77DnKxHZu8A/lJBdiB3QW0KtZB6awBdpUKD9jf1b0SHzUv
KBds0pjBqAlkd25HN7rOrFleaJ1/ctaJxQZBKT5ZPt0m9STJEadao0xAH0ahmbWn
OlFuhjuefXKnEgV4We0+UXgVCwOPjdAvBbI+e0ocS3MFEvzG6uBQE3xDk3SzynTn
jh8BCNAw1FtxNrQHusEwMFxIt4I7mKZ9YIqioymCzLq9gwQbooMDQaHWBfEbwrbw
qHyGO0aoSCqI3Haadr8faqU9GY/rOPNk3sgrDQoo//fb4hVC1CLQJ13hef4Y53CI
rU7m2Ys6xt0nUW7/vGT1M0NPAgMBAAGjQjBAMA4GA1UdDwEB/wQEAwIBBjAPBgNV
HRMBAf8EBTADAQH/MB0GA1UdDgQWBBR5tFnme7bl5AFzgAiIyBpY9umbbjANBgkq
hkiG9w0BAQsFAAOCAgEAVR9YqbyyqFDQDLHYGmkgJykIrGF1XIpu+ILlaS/V9lZL
ubhzEFnTIZd+50xx+7LSYK05qAvqFyFWhfFQDlnrzuBZ6brJFe+GnY+EgPbk6ZGQ
3BebYhtF8GaV0nxvwuo77x/Py9auJ/GpsMiu/X1+mvoiBOv/2X/qkSsisRcOj/KK
NFtY2PwByVS5uCbMiogziUwthDyC3+6WVwW6LLv3xLfHTjuCvjHIInNzktHCgKQ5
ORAzI4JMPJ+GslWYHb4phowim57iaztXOoJwTdwJx4nLCgdNbOhdjsnvzqvHu7Ur
TkXWStAmzOVyyghqpZXjFaH3pO3JLF+l+/+sKAIuvtd7u+Nxe5AW0wdeRlN8NwdC
jNPElpzVmbUq4JUagEiuTDkHzsxHpFKVK7q4+63SM1N95R1NbdWhscdCb+ZAJzVc
oyi3B43njTOQ5yOf+1CceWxG1bQVs5ZufpsMljq4Ui0/1lvh+wjChP4kqKOJ2qxq
4RgqsahDYVvTH9w7jXbyLeiNdd8XM2w9U/t7y0Ff/9yi0GE44Za4rF2LN9d11TPA
mRGunUHBcnWEvgJBQl9nJEiU0Zsnvgc/ubhPgXRR4Xq37Z0j4r7g1SgEEzwxA57d
emyPxgcYxn/eR44/KJ4EBs+lVDR3veyJm+kXQ99b21/+jh5Xos1AnX5iItreGCc=
-----END CERTIFICATE-----
)EOF";

void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Conectando a ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi conectado");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Mensaje recibido en el canal: ");
  Serial.println(topic);

  // Convertir el payload a string
  String mensaje;
  for (unsigned int i = 0; i < length; i++) {
    mensaje += (char)payload[i];
  }

  Serial.print("Contenido del mensaje: ");
  Serial.println(mensaje);

  // Condiciones para encender o apagar LEDs según los datos del mensaje
  if (strcmp(topic, CONTROL_BUZZER) == 0) {
    int estado = mensaje.toInt();
    digitalWrite(buzzerPin, estado);
    Serial.print("Estado del Buzzer: ");
    Serial.println(estado);
  }

  // Control del LED rojo (alta temperatura)
  if (strcmp(topic, "Sensores/TempHum") == 0) {
    float temperatura = mensaje.substring(6, mensaje.indexOf("C")).toFloat();  // Extraer la temperatura del mensaje
    if (temperatura > 30) {
      digitalWrite(ledRojoPin, HIGH);   // Enciende el LED rojo
      digitalWrite(ledAzulPin, LOW);    // Apaga el LED azul
    } else if (temperatura < 20) {
      digitalWrite(ledAzulPin, HIGH);   // Enciende el LED azul
      digitalWrite(ledRojoPin, LOW);    // Apaga el LED rojo
    } else {
      digitalWrite(ledRojoPin, LOW);    // Apaga el LED rojo
      digitalWrite(ledAzulPin, LOW);    // Apaga el LED azul
    }
    Serial.print("Temperatura: ");
    Serial.println(temperatura);
  }

  // Control del LED blanco (nivel de luz)
  if (strcmp(topic, "Sensores/Luz") == 0) {
    int luzNivel = mensaje.toInt();
    if (luzNivel < 20) {
      digitalWrite(ledBlancoPin, HIGH);  // Enciende el LED blanco si hay poca luz
    } else {
      digitalWrite(ledBlancoPin, LOW);   // Apaga el LED blanco si hay suficiente luz
    }
    Serial.print("Nivel de Luz: ");
    Serial.println(luzNivel);
  }

  // Control del buzzer (detectar gas)
  if (strcmp(topic, "Sensores/Gas") == 0) {
    int gasValor = mensaje.toInt();
    if (gasValor > 500) {
      digitalWrite(buzzerPin, HIGH);  // Enciende el buzzer si detecta gas
    } else {
      digitalWrite(buzzerPin, LOW);   // Apaga el buzzer si no hay gas detectado
    }
    Serial.print("Nivel de Gas: ");
    Serial.println(gasValor);
  }
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Intentando conexión MQTT...");
    if (client.connect("ESP32Client", mqtt_username, mqtt_password)) {
      Serial.println("conectado");
      client.subscribe(CONTROL_BUZZER);
      client.subscribe(CONTROL_SERVOMOTOR);
      client.subscribe(TOPICO_MQ2);
      client.subscribe(TOPICO_LUZ);
      client.subscribe(TOPICO_TEMPHUM);
    } else {
      Serial.print("fallo, rc=");
      Serial.print(client.state());
      Serial.println(" reintentando en 5 segundos");
      delay(5000);
    }
  }
}

void setup() {
  Serial.begin(115200);
  setup_wifi();

  pinMode(buzzerPin, OUTPUT);
  pinMode(ledBlancoPin, OUTPUT);
  pinMode(ledRojoPin, OUTPUT);
  pinMode(ledAzulPin, OUTPUT);

  // Configuración de la pantalla LCD
  lcd.begin(LCD_COLUMNS, LCD_ROWS);
  lcd.backlight();
  lcd.setCursor(0, 0);
  lcd.print("Conectando...");

  espClient.setCACert(root_ca);
  client.setServer(mqtt_server, mqtt_port);
  client.setCallback(callback);

  // Inicializar el sensor DHT
  dht.begin();
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  // Leer sensores
  float temperatura = dht.readTemperature();
  float humedad = dht.readHumidity();
  int luzValor = analogRead(ldrPin);
  int luzNivel = map(luzValor, 0, 4095, 100, 0);  // Escala a porcentaje
  int gasValor = analogRead(mq2Pin);

  // Condiciones para LEDs y buzzer
  if (luzNivel < 20) {  // Condición para luz baja
    digitalWrite(ledBlancoPin, HIGH);
  } else {
    digitalWrite(ledBlancoPin, LOW);
  }

  if (gasValor > 500) {  // Condición para detectar gas
    digitalWrite(buzzerPin, HIGH);
  } else {
    digitalWrite(buzzerPin, LOW);
  }

  if (temperatura > 30) {  // Condición para alta temperatura
    digitalWrite(ledRojoPin, HIGH);
    digitalWrite(ledAzulPin, LOW);
  } else if (temperatura < 20) {  // Condición para baja temperatura
    digitalWrite(ledAzulPin, HIGH);
    digitalWrite(ledRojoPin, LOW);
  } else {  // Apagar ambos LEDs si la temperatura es moderada
    digitalWrite(ledAzulPin, LOW);
    digitalWrite(ledRojoPin, LOW);
  }

  // Publicar valores de sensores en MQTT
  if (!isnan(temperatura) && !isnan(humedad)) {
    String payloadTempHum = "Temp: " + String(temperatura) + " C, Hum: " + String(humedad) + "%";
    client.publish(TOPICO_TEMPHUM, payloadTempHum.c_str());
  }
  client.publish(TOPICO_LUZ, String(luzNivel).c_str());
  client.publish(TOPICO_MQ2, String(gasValor).c_str());

  // Mostrar en LCD
  lcd.setCursor(0, 0);
  lcd.print("Temp: ");
  lcd.print(temperatura);
  lcd.print("C ");
  lcd.print("Hum: ");
  lcd.print(humedad);
  lcd.print("%   ");

  lcd.setCursor(0, 1);
  lcd.print("Luz: ");
  lcd.print(luzNivel);
  lcd.print("%       ");

  lcd.setCursor(0, 2);
  lcd.print("Gas: ");
  lcd.print(gasValor);
  lcd.print("      ");
  delay(6000);
}