/*
这段代码主要用于配置和读取MPU6050传感器的数据，包括加速度、陀螺仪和温度。

#include <Adafruit_MPU6050.h>
包含了Adafruit提供的MPU6050库，用于简化与MPU6050传感器的通信，封装了对MPU6050寄存器的操作和数据读取方法。

#include <Adafruit_Sensor.h>
包含了Adafruit传感器库的接口，定义了传感器事件的标准数据结构event，用于统一处理多种类型的传感器数据（如加速度、陀螺仪、温度等）。

#include <Wire.h>
包含了Arduino的I2C通信库，MPU6050使用I2C协议与Arduino通信，Wire库负责与I2C设备的数据传输。

虽然代码中没有显式调用Wire库的具体I2C读写函数（如Wire.begin()、Wire.read()等），
但这些底层I2C操作都已经封装在Adafruit_MPU6050库中。
具体来说，当你调用mpu.begin()时，Adafruit_MPU6050库会自动调用Wire.begin()
来初始化I2C通信，并通过I2C协议与MPU6050进行数据传输
在Arduino上，I2C通信的引脚是固定的，并且不同型号的Arduino板子对应不同的引脚：

Arduino Uno/Nano: SDA（数据线）引脚：A4 SCL（时钟线）引脚：A5
Arduino Mega 2560: SDA引脚：20 SCL引脚：21
Arduino Leonardo: SDA引脚：2 SCL引脚：3
Arduino Due: SDA引脚：20 SCL引脚：21

如果你使用的是某些特殊的Arduino兼容板，并且需要手动指定I2C引脚，
可以使用Wire.begin(SDA_pin, SCL_pin)来指定I2C通信的引脚。例如：
Wire.begin(4, 5);  // 手动指定SDA为4号引脚，SCL为5号引脚

ESP32 的 I2C 引脚是可以自由配置的，默认情况下并没有固定的 I2C 引脚。
这意味着你可以在代码中手动指定 SDA（数据线）和 SCL（时钟线）引脚。

不过，ESP32 通常的默认 I2C 引脚是：SDA（数据线）：GPIO 21 SCL（时钟线）：GPIO 22

*/

#include <Adafruit_MPU6050.h>
#include <Adafruit_Sensor.h>
#include <Wire.h>

// 创建MPU6050对象，通过它与MPU6050传感器进行交互
Adafruit_MPU6050 mpu;

void setup() {
  // put your setup code here, to run once:
  Serial.begin(115200);
  Serial.println("Adafruit MPU6050 test");

  // 初始化MPU6050传感器
  if(!mpu.begin()) {
    Serial.println("找不到MPU6050");
    while(1) {
      delay(10);
    }
  }

  Serial.println("MPU6050找到了！");

  // 设置加速度计的量程为±8G。
  // MPU6050支持的量程有±2G、±4G、±8G、±16G。
  // 量程设置影响传感器的灵敏度，较大的量程可测量更大的加速度，但精度会有所降低。
  mpu.setAccelerometerRange(MPU6050_RANGE_8_G);
  Serial.print(F("Accelerometer range set to: "));
  switch(mpu.getAccelerometerRange()){
    case MPU6050_RANGE_2_G:
      Serial.println("+-2G");
      break;
    case MPU6050_RANGE_4_G:
      Serial.println("+-4G");
      break;
    case MPU6050_RANGE_8_G:
      Serial.println("+-8G");
      break;
    case MPU6050_RANGE_16_G:
      Serial.println("+-16G");
      break;
  }

  // 设置陀螺仪的量程为±2000度/秒。
  // MPU6050支持的陀螺仪量程有±250、±500、±1000、±2000度/秒。
  // 较大的量程适合高速旋转的测量
  mpu.setGyroRange(MPU6050_RANGE_2000_DEG);
  Serial.print("Gyro ragne set to: ");
  switch(mpu.getGyroRange()){
    case MPU6050_RANGE_250_DEG:
      Serial.println("+- 250 deg/2");
      break;
    case MPU6050_RANGE_500_DEG:
      Serial.println("+- 500 deg/2");
      break;
    case MPU6050_RANGE_1000_DEG:
      Serial.println("+- 1000 deg/2");
      break;
    case MPU6050_RANGE_2000_DEG:
      Serial.println("+- 2000 deg/2");
      break;
  }

  // 设置数字低通滤波器的带宽为21Hz，用于过滤掉高频噪声，适合在低频应用中使用。
  // 带宽越低，信号越平滑，但响应速度也越慢
  mpu.setFilterBandwidth(MPU6050_BAND_21_HZ);
  Serial.print(F("Filter bandwidth set to: "));
  switch(mpu.getFilterBandwidth()){
    case MPU6050_BAND_260_HZ:
      Serial.println("260 Hz");
      break;
    case MPU6050_BAND_184_HZ:
      Serial.println("184 Hz");
      break;
    case MPU6050_BAND_94_HZ:
      Serial.println("94 Hz");
      break;
    case MPU6050_BAND_44_HZ:
      Serial.println("44 Hz");
      break;
    case MPU6050_BAND_21_HZ:
      Serial.println("21 Hz");
      break;
    case MPU6050_BAND_10_HZ:
      Serial.println("10 Hz");
      break;
    case MPU6050_BAND_5_HZ:
      Serial.println("5 Hz");
      break;
  }

  Serial.println("");
  delay(100);
}

void loop() {
  // put your main code here, to run repeatedly:

  /* Get new sensor events with the readings */
  // 定义了三个传感器事件结构体，分别用于存储加速度、陀螺仪和温度的读数
  sensors_event_t a, g, temp;
  // 调用getEvent函数，从MPU6050获取最新的加速度、陀螺仪和温度数据，并存储在对应的事件结构体中。
  mpu.getEvent(&a, &g, &temp);

  Serial.print("Acceleration X: ");
  Serial.print(a.acceleration.x);
  Serial.print(", Y: ");
  Serial.print(a.acceleration.y);
  Serial.print(", Z: ");
  Serial.print(a.acceleration.z);
  Serial.println(" m/s^2");

  Serial.print("Rotation X: ");
  Serial.print(g.gyro.x);
  Serial.print(", Y: ");
  Serial.print(g.gyro.y);
  Serial.print(", Z: ");
  Serial.print(g.gyro.z);
  Serial.println(" rad/s");

  Serial.print("Temperature: ");
  Serial.print(temp.temperature);
  Serial.println(" degC");

  Serial.println("");
  delay(500);
}