#include <LiquidCrystal.h>
#include <Keypad.h>

LiquidCrystal lcd(12, 11, 10, 9, 8, 7);

const byte KEYPAD_ROWS = 4;
const byte KEYPAD_COLS = 4;
byte rowPins[KEYPAD_ROWS] = {5, 4, 3, 2};
byte colPins[KEYPAD_COLS] = {A3, A2, A1, A0};
char keys[KEYPAD_ROWS][KEYPAD_COLS] = {
  {'1', '2', '3', '+'},
  {'4', '5', '6', '-'},
  {'7', '8', '9', '*'},
  {'C', '0', '=', '/'}
};

Keypad keypad = Keypad(makeKeymap(keys), rowPins, colPins, KEYPAD_ROWS, KEYPAD_COLS);

String input = "";
char operation = '\0';
float firstNumber = 0;
float secondNumber = 0;

void setup() {
  lcd.begin(16, 2);
  lcd.print("Kalkulator");
  delay(1000);
  lcd.clear();
}

void loop() {
  char key = keypad.getKey();

  if (key) {
    if (key >= '0' && key <= '9') {
      input += key;
      lcd.print(key);
    } else if (key == '+' || key == '-' || key == '*' || key == '/') {
      if (input != "") {
        firstNumber = input.toFloat();
        input = "";
        operation = key;
        lcd.clear();
        lcd.print(firstNumber);
        lcd.print(" ");
        lcd.print(operation);
      }
    } else if (key == '=') {
      if (input != "" && operation != '\0') {
        secondNumber = input.toFloat();
        float result = 0;

        switch (operation) {
          case '+':
            result = firstNumber + secondNumber;
            break;
          case '-':
            result = firstNumber - secondNumber;
            break;
          case '*':
            result = firstNumber * secondNumber;
            break;
          case '/':
            if (secondNumber != 0) {
              result = firstNumber / secondNumber;
            } else {
              lcd.clear();
              lcd.print("Error: /0");
              delay(2000);
              lcd.clear();
              resetCalculator();
              return;
            }
            break;
        }
        lcd.clear();
        lcd.print("Hasil: ");
        lcd.print(result);
        delay(2000);
        resetCalculator();
      }
    } else if (key == 'C') {
      resetCalculator();
    }
  }
}

void resetCalculator() {
  input = "";
  operation = '\0';
  firstNumber = 0;
  secondNumber = 0;
  lcd.clear();
}