#include <LiquidCrystal.h>
#include "DHTesp.h"

const int DHT_PIN = 2;
const int RED_PIN = 6;
const int GREEN_PIN = 5;
const int BLUE_PIN = 4;

DHTesp dhtSensor;

LiquidCrystal lcd(12, 11, 10, 9, 8, 7);

float previousTemp = 0.0;
float previousHumidity = 0.0;

void setup() {
  //LCD Setup
  lcd.begin(16, 2);
  Serial.begin(115200);
  dhtSensor.setup(DHT_PIN, DHTesp::DHT22);

  //RGB LED Setup
  pinMode(RED_PIN, OUTPUT);
  pinMode(GREEN_PIN, OUTPUT);
  pinMode(BLUE_PIN, OUTPUT);

  //Start with all LEDs off
  digitalWrite(RED_PIN, LOW);
  digitalWrite(GREEN_PIN, LOW);
  digitalWrite(BLUE_PIN, LOW);
}

void loop() {
  TempAndHumidity data = dhtSensor.getTempAndHumidity();

  //Check if a reading error exists
  if (isnan(data.humidity)) {
    Serial.println("Error reading humidity");
    
    //Turn Blue LED on for error
    setRGB(LOW, LOW, HIGH);
    
    //Display error
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("Error reading");
    lcd.setCursor(0, 1);
    lcd.print("sensor data");
  } else {
    // Output to the Serial Monitor
    Serial.println("Temp: " + String(data.temperature, 2) + "°C");
    Serial.println("Humidity: " + String(data.humidity, 1) + "%");
    Serial.println("---");
    
    //Update LCD only if values have changed
    if (data.temperature != previousTemp || data.humidity != previousHumidity) {
      lcd.clear();
      lcd.setCursor(0, 0); 
      lcd.print("Temp: " + String(data.temperature, 2) + " C");
      lcd.setCursor(0, 1); 
      lcd.print("Humidity: " + String(data.humidity, 1) + "%");

      //Update previous values
      previousTemp = data.temperature;
      previousHumidity = data.humidity;
    }

    //Control RGB LED based on humidity
    if (data.humidity >= 40 && data.humidity <= 60) {
      //Turn on green when humidity is between 40% and 60%
      setRGB(LOW, HIGH, LOW);
    } else {
      //Turn on red if humidity is outside the range
      setRGB(HIGH, LOW, LOW);
    }
  }
  
  delay(2000); 
}

//Function to control the RGB LED
void setRGB(bool red, bool green, bool blue) {
  digitalWrite(RED_PIN, red);
  digitalWrite(GREEN_PIN, green);
  digitalWrite(BLUE_PIN, blue);
}