#include <WiFi.h>
#include <PubSubClient.h>

// Konfigurasi WiFi
const char* ssid = "Wokwi-GUEST";
const char* password = "";

// Konfigurasi MQTT
const char* mqtt_server = "ferdi.cloud.shiftr.io";
const int mqtt_port = 1883;
const char* mqtt_user = "ferdi";   // Ganti dengan username Shiftr.io
const char* mqtt_password = "1234";  // Ganti dengan password Shiftr.io

WiFiClient espClient;
PubSubClient client(espClient);

#define RELAY1_PIN 13
#define RELAY2_PIN 12
#define RELAY3_PIN 14
#define RELAY4_PIN 27

void setup_wifi() {
  delay(10);
  Serial.println("Menghubungkan ke WiFi...");
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi terhubung!");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  String message = "";
  for (int i = 0; i < length; i++) {
    message += (char)payload[i];
  }
  
  String relay = String(topic).substring(String(topic).lastIndexOf('/') + 1);
  bool state = (message == "on");

  if (relay == "1") digitalWrite(RELAY1_PIN, state);
  if (relay == "2") digitalWrite(RELAY2_PIN, state);
  if (relay == "3") digitalWrite(RELAY3_PIN, state);
  if (relay == "4") digitalWrite(RELAY4_PIN, state);

  Serial.println("Relay " + relay + " diatur ke " + message);
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Menghubungkan ke broker MQTT...");
    if (client.connect("WokwiClient", mqtt_user, mqtt_password)) {
      Serial.println("Terhubung!");
      client.subscribe("wokwi/relay/#");
    } else {
      Serial.print("Gagal, rc=");
      Serial.print(client.state());
      Serial.println(" mencoba lagi dalam 5 detik");
      delay(5000);
    }
  }
}

void setup() {
  Serial.begin(115200);
  setup_wifi();

  pinMode(RELAY1_PIN, OUTPUT);
  pinMode(RELAY2_PIN, OUTPUT);
  pinMode(RELAY3_PIN, OUTPUT);
  pinMode(RELAY4_PIN, OUTPUT);

  client.setServer(mqtt_server, mqtt_port);
  client.setCallback(callback);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();
}