#include <WiFi.h>
#include "PubSubClient.h"

const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqttServer = "broker.emqx.io";
int port = 1883;
char clientId[50];

WiFiClient espClient;
PubSubClient client(espClient);

const int ledPin1 = 5;
const int ledPin2 = 4;
const int ledPin3 = 2;

#define sensorPin 34  

void setup() {
  Serial.begin(115200);

  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);
  wifiConnect();
  
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());

  client.setServer(mqttServer, port);
  client.setCallback(callback);

  pinMode(ledPin1, OUTPUT);
  pinMode(ledPin2, OUTPUT);
  pinMode(ledPin3, OUTPUT);
}

void wifiConnect() {
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
}

void mqttReconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    long r = random(1000);
    sprintf(clientId, "clientId-%ld", r);
    if (client.connect(clientId)) {
      Serial.print(clientId);
      Serial.println(" connected");
      client.subscribe("topicTRJT3B/42222030/led");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void callback(char* topic, byte* message, unsigned int length) {
  String stMessage = "";
  for (int i = 0; i < length; i++) {
    stMessage += (char)message[i];
  }
  Serial.print("Message arrived on topic: ");
  Serial.print(topic);
  Serial.print(". Message: ");
  Serial.println(stMessage);

  if (String(topic) == "topicTRJT3B/42222030/led") {
    Serial.print("Changing output to ");
    if (stMessage == "11") {
      Serial.println("LED 1 on");
      digitalWrite(ledPin1, HIGH);
    } else if (stMessage == "10") {
      Serial.println("LED 1 off");
      digitalWrite(ledPin1, LOW);
    } else if (stMessage == "21") {
      Serial.println("LED 2 on");
      digitalWrite(ledPin2, HIGH);
    } else if (stMessage == "20") {
      Serial.println("LED 2 off");
      digitalWrite(ledPin2, LOW);
    } else if (stMessage == "31") {
      Serial.println("LED 3 on");
      digitalWrite(ledPin3, HIGH);
    } else if (stMessage == "30") {
      Serial.println("LED 3 off");
      digitalWrite(ledPin3, LOW);
    }
  }
}

void loop() {
  if (!client.connected()) {
    mqttReconnect();
  }
  client.loop();

  int reading = analogRead(sensorPin);
  float voltage = reading * (3.3 / 4095.0);
  float temperatureC = voltage * 100;

  Serial.print("Temperature: ");
  Serial.print(temperatureC);
  Serial.print("\xC2\xB0");
  Serial.println("C");

  String tempStr = String(temperatureC);
  client.publish("topicTRJT3B/42222030/suhu", tempStr.c_str());

  delay(1000);
}