#include "WiFi.h"
#include "PubSubClient.h"
#include "DHT.h"

// MQTT Broker thông tin
const char *MQTTServer = "broker.emqx.io"; // Broker MQTT
const char *MQTT_Topic = "/farm/1/temperature";
const char *mqtt_username = "huuthocse";
const char *mqtt_password = "123456";
const char *MQTT_ID = "4565e61c-efdb-4d8a-b7d4-1712042346b0";
const int Port = 1883; // Cổng MQTT

// WiFi và MQTT client
WiFiClient espClient;
PubSubClient client(espClient);

// DHT22 cảm biến
#define DHTPIN 21
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE);

// Thời gian gửi dữ liệu
unsigned long previousMillis = 0;
const long interval = 10000; // Gửi dữ liệu mỗi 10 giây

// Hàm kết nối WiFi
void WIFIConnect() {
  Serial.print("Connecting to WiFi: ");
  Serial.println("Wokwi-GUEST");
  WiFi.begin("Wokwi-GUEST", ""); // SSID và Password WiFi
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("\nWiFi connected, IP: ");
  Serial.println(WiFi.localIP());
}

// Hàm kết nối MQTT
void MQTT_Reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    if (client.connect(MQTT_ID, mqtt_username, mqtt_password)) {
      Serial.println(" connected");
      client.subscribe(MQTT_Topic); // Subscribe nếu cần
    } else {
      Serial.print(" failed (rc=");
      Serial.print(client.state());
      Serial.println("). Retrying in 5 seconds...");
      delay(5000);
    }
  }
}

// Hàm đọc và gửi dữ liệu từ cảm biến
void sendSensorData() {
  float temperature = dht.readTemperature();
  float humidity = dht.readHumidity();

  if (isnan(temperature) || isnan(humidity)) {
    Serial.println("Failed to read from DHT sensor!");
    return;
  }

  // Tạo thông điệp JSON
  char message[50];
  snprintf(message, sizeof(message), "{\"temperature\": %.2f, \"humidity\": %.2f}", temperature, humidity);

  // Gửi thông điệp qua MQTT
  if (client.publish(MQTT_Topic, message)) {
    Serial.print("Message sent: ");
    Serial.println(message);
  } else {
    Serial.println("Failed to send message!");
  }
}

void setup() {
  Serial.begin(115200);
  dht.begin(); // Khởi động cảm biến DHT

  WIFIConnect(); // Kết nối WiFi
  client.setServer(MQTTServer, Port); // Cấu hình MQTT server
}

void loop() {
  if (!client.connected()) {
    MQTT_Reconnect();
  }
  client.loop();

  // Gửi dữ liệu theo chu kỳ
  unsigned long currentMillis = millis();
  if (currentMillis - previousMillis >= interval) {
    previousMillis = currentMillis;
    sendSensorData();
  }
}