#include <Adafruit_SSD1306.h>
#include <ezButton.h>
#include <EEPROM.h> // Library for accessing internal EEPROM

#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 32 // OLED display height, in pixels
#define OLED_RESET     -1 // Reset pin # (or -1 if sharing Arduino reset pin)
#define SCREEN_ADDRESS 0x3C ///< See datasheet for Address; 0x3D for 128x64, 0x3C for 128x32
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

const int BUTTON_NUM = 2;

const int BUTTON_7(7),BUTTON_8(8);
ezButton buttonArray[] = {
  ezButton(BUTTON_7),
  ezButton(BUTTON_8)
};

int state[BUTTON_NUM], laststate[BUTTON_NUM];
unsigned long but_time[BUTTON_NUM], step_time[BUTTON_NUM], viewtime, EEPWrite_time;
const unsigned long STEP_TIME(30);
int viewValue, lastValue;
const byte minTemp(30), maxTemp(220);
bool flagWriteEPP;

void setup() {
  Serial.begin(9600);
  // SSD1306_SWITCHCAPVCC = generate display voltage from 3.3V internally
  if(!display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS)) {
    Serial.println(F("SSD1306 allocation failed"));
    for(;;); // Don't proceed, loop forever
  }
  display.setTextSize(1);             // Normal 1:1 pixel scale
  display.setTextColor(SSD1306_WHITE);        // Draw white text
  display.cp437(true);         // Use full 256 char 'Code Page 437' font

  for (byte i = 0; i < BUTTON_NUM; i++) {
    buttonArray[i].setDebounceTime(20); // set debounce time to 50 milliseconds
  }
  viewValue = EEPROM.read(0);
  lastValue = viewValue;
}

void loop() {
  unsigned long currentTime = millis();
  for (byte i = 0; i < BUTTON_NUM; i++)
    buttonArray[i].loop(); // MUST call the loop() function first

  for (byte i = 0; i < BUTTON_NUM; i++) {
    state[i] = buttonArray[i].getState();
    if (state[i] < laststate[i]) {
      but_time[i] = currentTime;
      changeValue(i);
    }
    if (state[i] == 0 && currentTime - but_time[i] > 600){
      if (currentTime - step_time[i] > STEP_TIME) {
        step_time[i] = currentTime;
        changeValue(i);
      }
    }
    laststate[i] = state[i];
  }
  if (currentTime - viewtime > STEP_TIME){
    viewtime = currentTime;
    mainDisplay();
  }

  if (lastValue != viewValue){
    lastValue = viewValue;
    EEPWrite_time = currentTime;
    flagWriteEPP = true;
  }
  
  if (currentTime - EEPWrite_time > 30000 && flagWriteEPP) {
    flagWriteEPP = false;
    int EEPValue = EEPROM.read(0);
    if (viewValue != EEPValue) EEPROM.write(0, (byte)viewValue);
  }
}

void mainDisplay() {
  // Clear the buffer
  display.clearDisplay();
  display.setCursor(0, 0);     // Start at top-left corner
  display.println(viewValue);
  display.display();
}

void changeValue(byte j) {
  viewValue += j?1:-1;
  if (viewValue > maxTemp) viewValue = maxTemp;
  if (viewValue < minTemp) viewValue = minTemp;
}