#include <LiquidCrystal.h>
#include <Keypad.h>
#include <math.h>
#include "SafeState.h"
#include "icons.h"

#define BUZZER_PIN 6

void playSuccessTone() {
  tone(BUZZER_PIN, 1000, 200);
}

void playErrorTone() {
  tone(BUZZER_PIN, 500, 1000);
}

void playBlockedTone() {
  for (int i = 0; i < 5; i++) {
    tone(BUZZER_PIN, 1500, 200);
    delay(300);
  }
}

LiquidCrystal lcd(12, 11, 10, 9, 8, 7);

const byte KEYPAD_ROWS = 4;
const byte KEYPAD_COLS = 4;
byte rowPins[KEYPAD_ROWS] = {5, 4, 3, 2};
byte colPins[KEYPAD_COLS] = {A3, A2, A1, A0};
char keys[KEYPAD_ROWS][KEYPAD_COLS] = {
  {'1', '2', '3', 'A'},
  {'4', '5', '6', 'B'},
  {'7', '8', '9', 'C'},
  {'*', '0', '#', 'D'}
};

Keypad keypad = Keypad(makeKeymap(keys), rowPins, colPins, KEYPAD_ROWS, KEYPAD_COLS);

SafeState safeState;
String masterCode = "1234"; // Заранее установленный мастер-код
int failedAttempts = 0;
unsigned long blockUntilTime = 0;
bool wasUnlockedWithMasterCode = false;

void showStartupMessage() {
  lcd.setCursor(2, 0);
  lcd.print("Good Morning!");
  delay(1000);

  lcd.setCursor(2, 2);
  String message = "Artem Aliyev";
  for (byte i = 0; i < message.length(); i++) {
    lcd.print(message[i]);
    delay(100);
  }
  delay(500);
}

String inputSecretCode() {
  lcd.setCursor(5, 1);
  lcd.print("[____]");
  lcd.setCursor(6, 1);
  String result = "";
  while (result.length() < 4) {
    char key = keypad.getKey();
    if (key >= '0' && key <= '9') {
      lcd.print('*');
      result += key;
    }
  }
  return result;
}

void showWaitScreen(int delayMillis) {
  lcd.setCursor(2, 1);
  lcd.print("[..........]");
  lcd.setCursor(3, 1);
  for (byte i = 0; i < 10; i++) {
    delay(delayMillis);
    lcd.print("=");
  }
}

bool setNewCode() {
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Enter new code:");
  String newCode = inputSecretCode();

  // Проверка на совпадение с мастер-кодом
  if (newCode.equals(masterCode)) {
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("Error: Can't use");
    lcd.setCursor(0, 1);
    lcd.print("Master Code!");
    delay(2000);
    return false;
  }

  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Confirm new code");
  String confirmCode = inputSecretCode();

  if (newCode.equals(confirmCode)) {
    safeState.setCode(newCode);
    return true;
  } else {
    lcd.clear();
    lcd.setCursor(1, 0);
    lcd.print("Code mismatch");
    lcd.setCursor(0, 1);
    lcd.print("Safe not locked!");
    delay(2000);
    return false;
  }
}

bool setMasterCode() {
  // Получаем текущий пользовательский пароль
  String currentUserCode = safeState.getCode();

  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Enter new");
  lcd.setCursor(0, 1);
  lcd.print("master code:");
  String newMasterCode = inputSecretCode();

  // Проверка на совпадение с текущим пользовательским паролем
  if (newMasterCode.equals(currentUserCode)) {
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("Error: Can't use");
    lcd.setCursor(0, 1);
    lcd.print("User Code!");
    delay(2000);
    return false;
  }

  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Confirm master");
  lcd.setCursor(0, 1);
  lcd.print("code:");
  String confirmMasterCode = inputSecretCode();

  if (newMasterCode.equals(confirmMasterCode)) {
    masterCode = newMasterCode; 
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("Master code");
    lcd.setCursor(0, 1);
    lcd.print("updated!");
    delay(2000);
    return true;
  } else {
    lcd.clear();
    lcd.setCursor(1, 0);
    lcd.print("Code mismatch");
    lcd.setCursor(0, 1);
    lcd.print("Master not changed");
    delay(2000);
    return false;
  }
}

void showUnlockMessage(bool isMasterCode) {
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.write(ICON_UNLOCKED_CHAR);
  lcd.setCursor(4, 0);
  lcd.print("Unlocked!");
  lcd.setCursor(15, 0);
  lcd.write(ICON_UNLOCKED_CHAR);

  if (isMasterCode) {
    lcd.setCursor(0, 1);
    lcd.print("Master Code Used");
  }

  delay(2000);
}

void safeUnlockedLogic() {
  lcd.clear();

  lcd.setCursor(0, 0);
  lcd.write(ICON_UNLOCKED_CHAR);
  lcd.setCursor(2, 0);
  lcd.print(" # to lock");
  lcd.setCursor(15, 0);
  lcd.write(ICON_UNLOCKED_CHAR);

  bool newCodeNeeded = true;

  if (safeState.hasCode()) {
    lcd.setCursor(0, 1);
    if (wasUnlockedWithMasterCode) {
      lcd.print("A=user B=master");
    } else {
      lcd.print("  A = new code");
    }
    newCodeNeeded = false;
  }

  char key;
  while (true) {
    key = keypad.getKey();
    if (key == 'A' || key == 'B' || key == '#') break;
  }

  bool readyToLock = true;
  if (key == 'A' || newCodeNeeded) {
    readyToLock = setNewCode();
  }
  
  if (wasUnlockedWithMasterCode && key == 'B') {
    readyToLock = setMasterCode();
    wasUnlockedWithMasterCode = false;
  }

  if (readyToLock) {
    lcd.clear();
    lcd.setCursor(5, 0);
    lcd.write(ICON_UNLOCKED_CHAR);
    lcd.print(" ");
    lcd.write(ICON_RIGHT_ARROW);
    lcd.print(" ");
    lcd.write(ICON_LOCKED_CHAR);

    safeState.lock();
    showWaitScreen(100);
  }
}

void safeLockedLogic() {
  if (millis() < blockUntilTime) {
    unsigned long timeLeft = ceil((blockUntilTime - millis()) / 1000.0);
    
    if (timeLeft > 30) timeLeft = 30;

    lcd.clear();
    lcd.setCursor(2, 0);
    lcd.print("Blocked!");
    lcd.setCursor(1, 1);
    lcd.print("Wait ");
    lcd.print(timeLeft);
    lcd.print(" sec...");
    playBlockedTone();
    return;
  }

  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.write(ICON_LOCKED_CHAR);
  lcd.print(" Safe Locked! ");
  lcd.write(ICON_LOCKED_CHAR);

  String userCode = inputSecretCode();

  if (userCode.equals(masterCode)) {
    safeState.unlock(userCode);
    showUnlockMessage(true);
    playSuccessTone();
    failedAttempts = 0;
    wasUnlockedWithMasterCode = true;
    return;
  }

  bool unlockedSuccessfully = safeState.unlock(userCode);
  showWaitScreen(200);

  if (unlockedSuccessfully) {
    showUnlockMessage(false);
    playSuccessTone();
    failedAttempts = 0;
    wasUnlockedWithMasterCode = false;
  } else {
    failedAttempts++;
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("Access Denied!");
    playErrorTone();
    if (failedAttempts >= 3) {
      blockUntilTime = millis() + 40000;  
      failedAttempts = 0;
    }
    showWaitScreen(1000);
  }
}

void setup() {
  lcd.begin(16, 2);
  init_icons(lcd);

  pinMode(BUZZER_PIN, OUTPUT);

  Serial.begin(115200);
  showStartupMessage();
}

void loop() {
  if (safeState.locked()) {
    safeLockedLogic();
  } else {
    safeUnlockedLogic();
  }
}