#include <WiFi.h>
#include <DHT.h>
#include <PubSubClient.h>


const char* ssid = "Wokwi-GUEST";           // SSID WiFi
const char* password = "";   // Password WiFi


#define TOKEN "mKVB0pUecBTB9AdetDc4"     
#define THINGSBOARD_SERVER "eu.thingsboard.cloud"


#define DHT_PIN 15
#define DHT_TYPE DHT22

DHT dht(DHT_PIN, DHT_TYPE);


WiFiClient espClient;
PubSubClient client(espClient);

// Fungsi untuk koneksi ke WiFi
void connectToWiFi() {
  Serial.println("Connecting to WiFi...");
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.print(".");
  }
  Serial.println("\nConnected to WiFi!");
}

// Fungsi untuk menghubungkan ke MQTT ThingsBoard
void connectToThingsBoard() {
  Serial.println("Connecting to ThingsBoard...");

  while (!client.connected()) {
    if (client.connect("ESP32", TOKEN, NULL)) {
      Serial.println("Connected to ThingsBoard!");
    } else {
      Serial.print("Failed to connect, rc=");
      Serial.print(client.state());
      Serial.println(" Trying again in 5 seconds...");
      delay(5000);
    }
  }
}

// Fungsi untuk mengirimkan data ke ThingsBoard
void sendTelemetryData(float temperature, float humidity) {
  char payload[256];
  snprintf(payload, sizeof(payload), "{\"temperature\": %.2f, \"humidity\": %.2f}", temperature, humidity);
  
  client.publish("v1/devices/me/telemetry", payload);
}

void setup() {
  Serial.begin(115200);
  dht.begin();
  
  connectToWiFi();
  
  client.setServer(THINGSBOARD_SERVER, 1883);
}

void loop() {
  if (!client.connected()) {
    connectToThingsBoard();
  }
  
  client.loop();
  
  // Membaca data DHT22
  float humidity = dht.readHumidity();
  float temperature = dht.readTemperature();

  Serial.print("Temperature: ");
  Serial.print(temperature);
  Serial.println(" °C  ");
  Serial.print("Humidity: ");
  Serial.print(humidity);
  Serial.println(" %");

  // Jika pembacaan gagal
  if (isnan(humidity) || isnan(temperature)) {
    Serial.println("Failed to read from DHT sensor!");
    return;
  }

  // Kirim data telemetry ke ThingsBoard
  sendTelemetryData(temperature, humidity);
  
  delay(5000);
}