#include <WiFi.h>
#include <WiFiClient.h>
#include <PubSubClient.h>

#define WIFI_SSID "Wokwi-GUEST"
#define WIFI_PASSWORD ""
// Defining the WiFi channel speeds up the connection:
#define WIFI_CHANNEL 6

#define BUTTON1_PIN 33
#define BUTTON2_PIN 34

bool boton1 = false;
bool boton2 = false;

// constantes del MQTT
// direccion broker, puerto, y nombre cliente
const char *MQTT_BROKER_ADRESS = "test.mosquitto.org";
const uint16_t MQTT_PORT = 1883;
const char *MQTT_CLIENT_NAME = "PLL2";

// instanciar objetos
WiFiClient espClient;
PubSubClient mqttClient(espClient);

String payload;
String content = "";

void ConnectWiFi()
{
  WiFi.begin(WIFI_SSID, WIFI_PASSWORD, WIFI_CHANNEL);
  Serial.print("Connecting to WiFi ");
  Serial.print(WIFI_SSID);
  // Wait for connection
  while (WiFi.status() != WL_CONNECTED)
  {
    delay(100);
    Serial.print(".");
  }
  Serial.println(" Connected!");

  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
}

void InitMqtt()
{
  mqttClient.setServer(MQTT_BROKER_ADRESS, MQTT_PORT);
}

void ConnectMqtt()
{
  while (!mqttClient.connected())
  {
    Serial.print("Starting MQTT connection...");
    if (mqttClient.connect(MQTT_CLIENT_NAME))
    {
      Serial.print("Client connected");
    }
    else
    {
      Serial.print("Failed MQTT connection, rc=");
      Serial.print(mqttClient.state());
      Serial.println(" try again in 5 seconds");

      delay(5000);
    }
  }
}

void HandleMqtt()
{
  if (!mqttClient.connected())
  {
    ConnectMqtt();
  }
  mqttClient.loop();
}

void PublishMqtt(int data)
{
  payload = "";
  payload = String(data);
  mqttClient.publish("pll/LEDs", (char *)payload.c_str());
}

void IRAM_ATTR ISRButton1()
{
  boton1 = true;
}

void IRAM_ATTR ISRButton2()
{
  boton2 = true;
}

void setup(void)
{
  Serial.begin(115200);
  pinMode(BUTTON1_PIN, INPUT_PULLUP);
  pinMode(BUTTON2_PIN, INPUT_PULLUP);
  attachInterrupt(digitalPinToInterrupt(BUTTON1_PIN), ISRButton1, FALLING);
  attachInterrupt(digitalPinToInterrupt(BUTTON2_PIN), ISRButton2, FALLING);
  ConnectWiFi();

  InitMqtt();

}

void loop()
{
  HandleMqtt();

  if (boton1)
  {
    PublishMqtt(1);
    boton1 = false;
  }

  if (boton2)
  {
    PublishMqtt(2);
    boton2 = false;
  }
  delay(100);
}