#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <Keypad.h>


const char* ssid       = "Wokwi-GUEST";
const char* password   = "";
const char* MQTTServer = "broker.emqx.io";
const char* MQTT_Topic = "topic/keypadT";
const char* MQTT_ID    = "87da673e-8ad2-4def-9156-ade5b6451773";
int         MQTT_Port  = 1883;

LiquidCrystal_I2C lcd(0x27, 20, 4);
const byte ROWS = 4;
const byte COLS = 4;
char keys[ROWS][COLS] = {
  {'1','2','3','A'},
  {'4','5','6','B'},
  {'7','8','9','C'},
  {'*','0','#','D'}
};


byte rowPins[ROWS] = {19, 18, 5, 17};
byte colPins[COLS] = {16, 4, 2, 15};

Keypad keypad = Keypad(makeKeymap(keys), rowPins, colPins, ROWS, COLS);


#define LED_PIN 13


WiFiClient espClient;
PubSubClient client(espClient);


void callback(char* topic, byte* message, unsigned int length) {
  Serial.print("Nhận MQTT [");
  Serial.print(topic);
  Serial.print("]: ");
  
  String messageTemp;
  for (int i = 0; i < length; i++) {
    messageTemp += (char)message[i];
  }
  Serial.println(messageTemp);

  
  int sepIndex = messageTemp.indexOf('|');
  if (sepIndex > 0) {
    String hovaten = messageTemp.substring(0, sepIndex);
    String mssv    = messageTemp.substring(sepIndex + 1);

    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("Ho ten: " + hovaten);
    lcd.setCursor(0, 2);
    lcd.print("MSSV: " + mssv);

  } else if (messageTemp.equalsIgnoreCase("ON")) {
    
    digitalWrite(LED_PIN, HIGH);
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("MQTT msg: ON");
    lcd.setCursor(0, 1);
    lcd.print("LED da bat");

  } else if (messageTemp.equalsIgnoreCase("OFF")) {
    
    digitalWrite(LED_PIN, LOW);
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("MQTT msg: OFF");
    lcd.setCursor(0, 1);
    lcd.print("LED da tat");

  } else {
    
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("MQTT msg:");
    lcd.setCursor(0, 1);
    lcd.print(messageTemp);
  }
}


void WIFIConnect() {
  Serial.print("Đang kết nối WiFi: ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("\nWiFi đã kết nối!");
  Serial.print("Địa chỉ IP: ");
  Serial.println(WiFi.localIP());
}


void MQTT_Reconnect() {
  while (!client.connected()) {
    Serial.print("Đang kết nối MQTT...");
    if (client.connect(MQTT_ID)) {
      Serial.println("Thành công!");
      
      client.subscribe(MQTT_Topic);
    } else {
      Serial.print("Thất bại, mã lỗi = ");
      Serial.print(client.state());
      Serial.println(" => Thử lại sau 5s");
      delay(5000);
    }
  }
}

void setup() {
  Serial.begin(115200);
  pinMode(LED_PIN, OUTPUT);
  digitalWrite(LED_PIN, LOW);
  Wire.begin(21, 22);
  lcd.init();
  lcd.backlight();
  lcd.clear();
  WIFIConnect();
  client.setServer(MQTTServer, MQTT_Port);
  client.setCallback(callback);
}
void loop() {
  if (!client.connected()) {
    MQTT_Reconnect();
  }
  client.loop();
  char key = keypad.getKey();
  if (key) {
    Serial.print("Keypad nhan: ");
    Serial.println(key);
    lcd.setCursor(0, 2);
    lcd.print("Keypad: ");
    lcd.print(key);
    // Publish phím bấm
    String msg = "Phim vua nhan: ";
    msg += key;
    client.publish(MQTT_Topic, msg.c_str());
  }
  delay(100);
}