#include <WiFi.h>
#include "PubSubClient.h"
#include "ArduinoJson.h"
#include <LiquidCrystal_I2C.h>
#include "DHTesp.h"
// khai bao broker
const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqttServer = "broker.hivemq.com";
int port = 1883;
const char* topic_name="20242173M"; // toptic publish giá trị nhiệt độ, độ ẩm
const char* topic_name2="LED/ON/OFF";//topic subcribe gia tri den led
// các biên phụ client và địa chỉ mac
String stMac;
char mac[50];
char clientId[50];
// khai báo chân pin
#define dht_pin 27 //khai bao chân pin của dht
#define pir_sensor 25 // khai báo chân pin của pir
#define ledPin 32 // chân pin led 1
#define ledPin2 33 // chân pin led 2
#define LED_PIN 26 // chan pin cho den led cam bien pir
// 
WiFiClient espClient;
PubSubClient client(espClient);
DHTesp dhtSensor; // khởi tạo biến dhtsensor
LiquidCrystal_I2C lcd(0x27,20,4);  // khai báo định dạng của màn hình LED
//
void setup() {
  // khai báo các chân pin
  pinMode(pir_sensor, INPUT);
  pinMode(ledPin, OUTPUT);
  pinMode(ledPin2, OUTPUT);
  pinMode(LED_PIN, OUTPUT);
  //
  Serial.begin(115200); // khởi tạo giao tiếp
  randomSeed(analogRead(0));
  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);
  wifiConnect();
  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  Serial.println(WiFi.macAddress());
  stMac = WiFi.macAddress();
  stMac.replace(":", "_");
  Serial.println(stMac);
  client.setServer(mqttServer, port);
  client.setCallback(callback);
  //
  lcd.init(); // khới tạo biến LCD
  // xuất giá trị lên LCD
  lcd.backlight();
  lcd.setCursor(1,0); // khởi tạo vị trí con trỏ trên màn hình LCD
  lcd.print("ESP lay du lieu !!"); // in dòng chữ bắt đầu từ vị trí con trỏ
  // khai bao dht
  dhtSensor.setup(dht_pin, DHTesp::DHT22); // khai báo cảm biến với chân pin đã nêu.
    delay(1000); // delay  1s
}
void wifiConnect() {
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
}
void mqttReconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    sprintf(clientId, "clientId_%s", stMac.c_str());
    Serial.print("Client ID: ");
    Serial.println(clientId);  // Debug dòng clientId
    if (client.connect(clientId)) {
      Serial.print(clientId);
      Serial.println(" connected");
      client.subscribe(topic_name2);
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}
void callback(char* topic, byte* message, unsigned int length) {
  Serial.print("Message arrived on topic: ");
  Serial.print(topic);
  Serial.print(". Message: ");
  String stMessage;
    for (int i = 0; i < length; i++) {
    Serial.print((char)message[i]);
    stMessage += (char)message[i];
  }
  Serial.println();

  if (String(topic) == topic_name2) {
    StaticJsonDocument<200> doc;
    DeserializationError error = deserializeJson(doc, stMessage);
    if (error) {
      Serial.print(F("deserializeJson failed: "));
      Serial.println(error.f_str());
      return;
    }
    int val1 = doc["led1"];
    int val2 = doc["led2"];
    Serial.println(val2);
    Serial.print("Changing output to ");
    if(val1 == 1){
      Serial.println("LED 1 on");
      digitalWrite(ledPin, HIGH);
    }
    else if(val1 == 0){
      Serial.println("LED 1 off");
      digitalWrite(ledPin, LOW);
    }
    if(val2 == 1){ 
      Serial.println("LED 2 on");
      digitalWrite(ledPin2, HIGH);
    }
    else{
      Serial.println("LED 2 off");
      digitalWrite(ledPin2, LOW);
    }
  }
}
void loop() {
  delay(10);
  //lay thong tin nhiet do do am va hien thi len lcd
  TempAndHumidity  data = dhtSensor.getTempAndHumidity();
  float temp = data.temperature;
  float humid = data.humidity;
  String stemp = String(temp) + (char)223+ "C"; // chuyển dữ liệu sang dạng string
  String shumid = String(humid) + "%"; // chuyển dữ liệu sang dạng string
  // hiển thị giá trị ra màn hình LCD
  lcd.clear(); // xóa màn hình
  lcd.setCursor(0,0); // con trỏ lcd trở về đầu tiên
  lcd.print("Temp: "+stemp); 
  lcd.setCursor(0,1);
  lcd.print("Humid: "+ shumid);
  // đoạn lệnh xử lý tín hiệu từ sensor
  int pir_value = digitalRead(pir_sensor);
  if(pir_value == 1){
    Serial.println("Phát hiện chuyển động !!");
    digitalWrite(LED_PIN, HIGH); // Bật đèn led
    delay(100);
  }
  else{
    //Serial.println("Không có chuyển động.");
    digitalWrite(LED_PIN, LOW); // tắt đèn led
    delay(100);
  }
   //
  String data1 = "{Temperature: " + String(temp) + ", humidity:" + String(humid)+"}";
  if (!client.connected()) {
    mqttReconnect();
  }
  else{
    Serial.println("Gửi dữ liên lên broker....");
    client.publish(topic_name, data1.c_str());
    delay(5000);
  }
  client.loop();
}