#include "DHTesp.h"
#include <OneWire.h>
#include <DallasTemperature.h>
#include <WiFi.h>
#include <PubSubClient.h>

const char* ssid = "Wokwi-GUEST"; // เปลี่ยนชื่อไวไฟที่เชื่อมต่อ
const char* password = ""; //รหัสผ่านไวไฟ
const char* mqttServer = "mqtt-dashboard.com";   // ใช้ public MQTT broker

int port = 1883;
String stMac;
char mac[50];
char clientId[50]="clientId-HVepMr2Nb6";

const int DHT_PIN = 15;     // ขา DHT22
const int TONE_WIRE_BUS = 4; // ขา DS18B20

// สร้างอ็อบเจ็กต์
OneWire oneWire(TONE_WIRE_BUS);
DallasTemperature sensors(&oneWire);
DHTesp dhtSensor;

WiFiClient espClient;
PubSubClient client(espClient);

void setup() {
  Serial.begin(115200);
  randomSeed(analogRead(0));

  Serial.println("Connecting to WiFi...");
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("WiFi connected, IP: " + WiFi.localIP().toString());

  client.setServer(mqttServer, port);
  client.setCallback(callback);

  // เริ่มเซ็นเซอร์
  dhtSensor.setup(DHT_PIN, DHTesp::DHT22);
  sensors.begin();
}

void mqttReconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    long r = random(100);
    sprintf(clientId, "ESP32-%ld", r);
    if (client.connect(clientId)) {
      Serial.print(clientId);
      Serial.println("connected");
      // subscribe ถ้าจำเป็นต้องรับค่าจาก Node-RED
      client.subscribe("TempDH");
      client.subscribe("HumidityDH");
      client.subscribe("TempDS");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 sec");
      delay(5000);
    }
  }
}

void callback(char* topic, byte* message, unsigned int length) {
  Serial.print("Message arrived on topic: ");
  Serial.print(topic);
  Serial.print(". Message: ");
  String stMessage;
  for (int i = 0; i < length; i++) {
    stMessage += (char)message[i];
  }
  Serial.println(stMessage);
}

void loop() {
  if (!client.connected()) {
    mqttReconnect();
  }
  client.loop(); // สำคัญ! ให้ MQTT ทำงานตลอดเวลา

  // อ่านค่า DHT22
  TempAndHumidity data = dhtSensor.getTempAndHumidity();
  float tempDH = data.temperature;
  float humDH = data.humidity;

  // อ่านค่า DS18B20
  sensors.requestTemperatures();
  float tempDS = sensors.getTempCByIndex(0);

  // แสดงผลใน Serial Monitor
  Serial.println("DHT22 Temp: " + String(tempDH, 1) + " °C");
  Serial.println("DHT22 Hum : " + String(humDH, 1) + " %");
  Serial.println("DS18B20 Temp: " + String(tempDS, 1) + " °C");
  Serial.println("========================");

  // ส่งค่าไป MQTT (Node-RED จะ subscribe topic เหล่านี้ได้)
  client.publish("TempDH", String(tempDH).c_str());
  client.publish("HumidityDH", String(humDH).c_str());
  client.publish("TempDS", String(tempDS).c_str());

  delay(2000);
}