#include <PubSubClient.h>
#include <WiFi.h>
#include <LiquidCrystal_I2C.h>

#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels

// Declaration for SSD1306 display connected using I2C
#define OLED_RESET     -1 // Reset pin
#define SCREEN_ADDRESS 0x3C
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);




// WIFI config
const char* ssid = "Wokwi-GUEST";
const char* password = "";
WiFiClient wifiClient;
// MQTT client config
const char* mqttServer = "broker.hivemq.com";
const int mqttPort = 1883;
const char* mqttUser = "";
const char* mqttPassword = "";
const char* topic_sub = "JJ/Lab/counter";
PubSubClient mqttClient(wifiClient);

LiquidCrystal_I2C lcd(0x27, 16, 2);
int i = 0;

void setup_wifi() {
  // Start by connecting to a WiFi network
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println();
  Serial.print("WiFi connected on ");
  Serial.print("IP address: ");
  Serial.print(WiFi.localIP());
  Serial.print(" MAC address: ");
  Serial.println(WiFi.macAddress());
  displayLCD(0, 0, 1, WiFi.localIP().toString());
  //displayLCD(0, 1,0, WiFi.macAddress());
  //displayoled(int col, int row, int clear,int size, String info)
  displayoled(0, 5, 1,1, WiFi.localIP().toString());
  displayoled(0, 15, 0,1, WiFi.macAddress());
}

void reconnectMQTT() {
  // Loop until we're reconnected
  char mqttinfo[80];
  char clientId[100] = "\0";
  snprintf (mqttinfo, 75, "Attempting MQTT connection at %s:%d (%s/%s)...", mqttServer,
            mqttPort, mqttUser, mqttPassword);
  while (!mqttClient.connected()) {
    Serial.println(mqttinfo);
    sprintf(clientId, "ESP32Client-%04X", random(0xffff));
    if (mqttClient.connect(clientId)) {
      Serial.println("...MQTT Broker connected...");
      displayLCD(0, 0, 1, "MQTT connected");
      displayoled(0, 5, 1,1, "MQTT Connect");
      mqttClient.subscribe(topic_sub);
    } else {
      Serial.print("failed, rc=");
      Serial.print(mqttClient.state());
      Serial.println(" try again in 5 seconds");
      displayLCD(0, 0, 1, "Disconnect");
      displayLCD(0, 1, 0, "Try to connect...");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}

void mqttCallback(char* topic, byte* payload, unsigned int length) {
  char payloadMsg[128];
  Serial.print("Message arrived in topic: ");
  Serial.print(topic);
  Serial.print(" Message:");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
    payloadMsg[i] = (char) payload[i];
  }
  payloadMsg[length] = '\0';
  Serial.println();
  Serial.println("-----------------------");
  doProcess(payloadMsg);
}

void doProcess(String rcvMsg) {
  displayLCD(0, 0, 1, rcvMsg);
  displayoled(0, 5, 1,1, rcvMsg);
}

void initLCD() {
  lcd.init();
  lcd.backlight();
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Starting ...");
}

void displayLCD(int col, int row, int clear, String info) {
  if (clear == 1) {
    lcd.clear();
  }
  lcd.setCursor(col, row);
  lcd.print(info);
}

void initoled(){
  if (!display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS)) {
    Serial.println(F("SSD1306 allocation failed"));
    for (;;); // Don't proceed, loop forever
  }

  // Clear the buffer.
  display.clearDisplay();

  // Display Text
  display.setTextSize(1);
  display.setTextColor(WHITE);
  display.setCursor(0,28);
  display.println("Starting......");
  display.display();
}

void displayoled(int col, int row, int clear,int size, String info) {
  if (clear == 1) {
    display.clearDisplay();
  }

  // Display Text
  display.setTextSize(size);
  display.setTextColor(WHITE);
  display.setCursor(col, row);
  display.println(info);
  display.display();

}

void setup() {
  Serial.begin(115200);
  Serial.println("Hello, ESP32!");

  initoled();

  initLCD();
  setup_wifi();
  // setup MQTT
  mqttClient.setServer(mqttServer, mqttPort);
  mqttClient.setCallback(mqttCallback); // set the callback function
}

void loop() {
  if (!mqttClient.connected()) {
    reconnectMQTT();
  }
  mqttClient.loop();
  delay(50);
}