#include <DHT.h>
#include <NTPClient.h>
#include <PubSubClient.h>
#include <WiFi.h>
#include <WiFiUdp.h>

// Define NTP Client to get time
WiFiUDP ntpUDP;
NTPClient timeClient(ntpUDP);

// initial WIFI 
const char* ssid = "Wokwi-GUEST";
const char* password =  "";
WiFiClient espClient;

// initial MQTT client
const char* mqttServer = "mqtt.netpie.io";
const int mqttPort = 1883;
const char* clientID = "52861577-2e7f-420d-a206-5852447e804e";
const char* mqttUser = "SQ1CLEg8cEkQXcxU1RwP1bTnTQMwh3c7";
const char* mqttPassword = "T7PBkcaMRPB4xezp8tMUkzdHeJk8vmGe";
const char* topic_pub = "@msg/lab_ict_kps/sensor_data";
const char* topic_sub = "@msg/lab_ict_kps/command";
char msg[128];
String currentDateTime;
PubSubClient client(espClient);

// initial DHT sensor
#define DHTTYPE DHT22
const int DHT_PIN = 16;
DHT dht(DHT_PIN, DHTTYPE);

void setup_wifi() {
  delay(10);
  // We start by connecting to a WiFi network
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println();
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void reconnectMQTT() {
  // Loop until we're reconnected
  char mqttinfo[80];
  snprintf (mqttinfo, 75, "Attempting MQTT connection at %s:%d (%s/%s)...", mqttServer, mqttPort, mqttUser, mqttPassword);
  while (!client.connected()) {
    Serial.println(mqttinfo);
    String clientId = clientID;
    if (client.connect(clientId.c_str(), mqttUser, mqttPassword)) {
      Serial.println("...Connected");
      client.subscribe(topic_sub);
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}

void callback(char* topic, byte* payload, unsigned int length) { 
  Serial.print("Message arrived in topic: ");
  Serial.println(topic); 
  Serial.print("Message:");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }
  Serial.println();
  Serial.println("-----------------------");
}

void setup() {
  Serial.begin(115200);
  setup_wifi();
  client.setServer(mqttServer, mqttPort);
  client.setCallback(callback); 
  dht.begin();
  // Initialize a NTPClient to get time
  timeClient.begin();
  timeClient.setTimeOffset(25200);   // GMT +7
}

void loop() {
  delay(5000);
  if (!client.connected()) {
    reconnectMQTT();
  }
  client.loop();

  timeClient.update();
  currentDateTime = timeClient.getFormattedTime();
  
  float h = dht.readHumidity();
  float t = dht.readTemperature();
  if (isnan(h) || isnan(t)) {
    Serial.println("Failed to read from DHT sensor!");
    return;
  } else {
    Serial.print("Current humidity = ");
    Serial.print(h);
    Serial.print("% ,");
    Serial.print("temperature = ");
    Serial.print(t);
    Serial.println("C");
    snprintf (msg, 128, "{\"data\": {\"temp\": %.2f, \"humidity\": %.2f, \"timestamp\": \"%s\" }}", t, h, currentDateTime.c_str());
    Serial.println(msg);
    client.publish(topic_pub, msg);
  }
}