#include <WiFi.h>
#include <PubSubClient.h>
#include <DHTesp.h>

const int DHT_PIN = 13;
DHTesp dht;

const char* mqtt_server = "test.mosquitto.org";
const char* mqtt_topic_temp = "IFRS-Ibiruba/SistemasEmbarcados/2020007675/temperatura";
const char* mqtt_topic_hum = "IFRS-Ibiruba/SistemasEmbarcados/2020007675/umidade";

WiFiClient espClient;
PubSubClient client(espClient);

unsigned long lastSensorRead = 0;
unsigned long lastPublish = 0;

float tempValues[12] = {0};
float humValues[12] = {0};
int currentIndex = 0;

void setup_wifi() { //CONECTA O ESP EM UMA REDE WIFI
  delay(10);
  WiFi.mode(WIFI_STA);
  WiFi.begin("Wokwi-GUEST", "");

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi conectado");
  Serial.print("IP: ");
  Serial.println(WiFi.localIP());
}

void connect() { 
  while (!client.connected()) {
    Serial.print("Tentando conexão MQTT...");
    String clientId = "ESP32Client-";
    clientId += String(random(0xffff), HEX);
    if (client.connect(clientId.c_str())) {
      Serial.println("Conectado ao MQTT como " + clientId);
    } else {
      Serial.print("Falha, rc=");
      Serial.print(client.state());
      Serial.println(" Tentando novamente em 5 segundos");
      delay(5000);
    }
  }
}

void setup() {
  Serial.begin(115200);
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  dht.setup(DHT_PIN, DHTesp::DHT22);
}

void loop() {
  if (!client.connected()) {
    connect();
  }
  client.loop();

  unsigned long now = millis();

  //LER O SENSOR E GUARDAR OS VALORES
  if (now - lastSensorRead >= 500) {
    lastSensorRead = now;

    TempAndHumidity data = dht.getTempAndHumidity();

    if (isnan(data.temperature) || isnan(data.humidity)) {
      Serial.println("Falha ao ler do sensor DHT!");
      return;
    }

    tempValues[currentIndex] = data.temperature;
    humValues[currentIndex] = data.humidity;

    Serial.print("Leitura de temperatura: ");
    Serial.println(data.temperature);
    Serial.print("Leitura de umidade: ");
    Serial.println(data.humidity);

    currentIndex = (currentIndex + 1) % 12;
  }

  //CÁLCULO E PUBLICAÇÃO DAS MÉDIAS
  if (now - lastPublish >= 6000) {
    lastPublish = now;

    float tempSum = 0;
    float humSum = 0;

    for (int i = 0; i < 12; i++) {
      tempSum += tempValues[i];
      humSum += humValues[i];
    }

    float tempAvg = tempSum / 12;
    float humAvg = humSum / 12;

    String temp = String(tempAvg, 2);
    String hum = String(humAvg, 1);

    if (client.publish(mqtt_topic_temp, temp.c_str())) {
      Serial.print("Temperatura média publicada: ");
      Serial.println(temp);
    } else {
      Serial.println("Falha ao publicar temperatura média");
    }

    if (client.publish(mqtt_topic_hum, hum.c_str())) {
      Serial.print("Umidade média publicada: ");
      Serial.println(hum);
    } else {
      Serial.println("Falha ao publicar umidade média");
    }
  }
}