#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>

// Cấu hình LCD và cảm biến DHT
LiquidCrystal_I2C lcd(0x27, 20, 4);
#define DHT_PIN 13       
#define DHT_TYPE DHT22   
DHT dht(DHT_PIN, DHT_TYPE);

#define LED_PIN 4       
// Cấu hình WiFi và MQTT
const char *ssid = "Wokwi-GUEST";
const char *password = "";
const char *mqtt_server = "broker.hivemq.com";
const int mqtt_port = 1883;

const char *topic_led = "21004171/input";
const char *topic_lcd = "21004171/output";

WiFiClient espClient;
PubSubClient client(espClient);

// Biến lưu trạng thái và dữ liệu
unsigned long lastMsg = 0;
float temp = 0;
float hum = 0;

//Hàm kết nối WiFi
void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println();
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}
//Hàm kết nối MQTT
void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    String clientId = "ESP32Client-";
    clientId += String(random(0xffff), HEX);

    if (client.connect(clientId.c_str())) {
      Serial.println("Connected to MQTT broker");
      client.subscribe(topic_led);
      client.subscribe(topic_lcd);
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}
//Xử lý dữ liệu nhận qua MQTT

void callback(char *topic, byte *payload, unsigned int length) {
  Serial.print("Message arrived on topic: ");
  Serial.println(topic);
  String message = "";

  for (int i = 0; i < length; i++) {
    message += (char)payload[i];
  }
  Serial.print("Message: ");
  Serial.println(message);

  if (strcmp(topic, topic_led) == 0) {
    if (message == "0") {
      digitalWrite(LED_PIN, LOW);
      Serial.println("LED OFF");
    } else if (message == "1") {
      digitalWrite(LED_PIN, HIGH);
      Serial.println("LED ON");
    }
  } else if (strcmp(topic, topic_lcd) == 0) {
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("Message: ");
    lcd.setCursor(0, 1);
    lcd.print(message);
  }
}

void setup() {
  pinMode(LED_PIN, OUTPUT);
  Serial.begin(115200);

  lcd.init();
  lcd.backlight();
  dht.begin(); // Khởi tạo cảm biến DHT

  setup_wifi();
  client.setServer(mqtt_server, mqtt_port);
  client.setCallback(callback);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  unsigned long now = millis();
  if (now - lastMsg > 2000) {
    lastMsg = now;

    // Đọc nhiệt độ và độ ẩm từ cảm biến DHT
    temp = dht.readTemperature(); // Đọc nhiệt độ
    hum = dht.readHumidity();    // Đọc độ ẩm

    // Kiểm tra nếu dữ liệu đọc bị lỗi
    if (isnan(temp) || isnan(hum)) {
      Serial.println("Failed to read from DHT sensor!");
      return;
    }

    // Hiển thị lên LCD
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("Temp: ");
    lcd.print(temp);
    lcd.print(" C");
    lcd.setCursor(0, 1);
    lcd.print("Hum: ");
    lcd.print(hum);
    lcd.print(" %");

    // Gửi dữ liệu lên MQTT
    String tempStr = String(temp, 2);
    String humStr = String(hum, 2);
    client.publish("/PTIT_Test/p/temp1", tempStr.c_str());
    client.publish("/PTIT_Test/p/hum1", humStr.c_str());

    // In ra Serial Monitor
    Serial.print("Temperature: ");
    Serial.println(tempStr);
    Serial.print("Humidity: ");
    Serial.println(humStr);
  }
}