#include <WiFi.h>
#include <MQTT.h>
#include <ESP32Servo.h>
#include <NusabotSimpleTimer.h>
#include <DHTesp.h>

WiFiClient net;
MQTTClient client;
Servo servo;
NusabotSimpleTimer timer;
DHTesp dhtSensor;

const char ssid[] = "Wokwi-GUEST";
const char pass[] = "";

String Serial_number = "12345678";
int potensio, oldPotensio = 0;
// Pin GPIO
const int pinRed = 2;
const int pinGreen = 4;
const int pinBlue = 16;

const int pinLed = 13;
const int pinServo = 32;

const int pinPot = 33;
const int pinDHT = 25;

void setup() {
  pinMode(pinRed, OUTPUT);
  pinMode(pinGreen, OUTPUT);
  pinMode(pinBlue, OUTPUT);
  pinMode(pinLed, OUTPUT);
  pinMode(pinPot, INPUT);
  dhtSensor.setup(pinDHT, DHTesp::DHT22);
  servo.attach(pinServo, 500, 2400);
  
  WiFi.begin(ssid, pass);
  Serial.begin(9600);
  client.begin("tugasku2025.cloud.shiftr.io", net);
  client.onMessage(subscribe);

  timer.setInterval(1000, publisPot);
  timer.setInterval(2000, publisDHT);

  connect();
}

void loop() {
  client.loop();
  timer.run();
  if(!client.connected()){
    connect();
  }
  delay(10);
}

void publisPot(){
  potensio = analogRead(pinPot);
  if(potensio != oldPotensio){
    client.publish("tugasiot/"+Serial_number+"/potensio", String(potensio), false, 1);
    oldPotensio = potensio; // menampung nilai lama
 }  
}

void publisDHT(){
  TempAndHumidity  data = dhtSensor.getTempAndHumidity();
  client.publish("tugasiot/"+Serial_number+"/suhu", String(data.temperature, 2), true, 1);
  client.publish("tugasiot/"+Serial_number+"/kelembaban", String(data.humidity, 1), true, 1);
}

void subscribe(String &topik, String &data){
  if(topik == "tugasiot/"+Serial_number+"/led"){
    if(data == "hidup"){
      digitalWrite(pinLed, 1);
    }else if(data == "mati"){
      digitalWrite(pinLed, 0);
    }
  }

  if(topik == "tugasiot/"+Serial_number+"/servo"){
    int posServo = data.toInt();
    servo.write(posServo);
  }

}

void rgb(bool red, bool green, bool blue){
  digitalWrite(pinRed, red);
  digitalWrite(pinGreen, green);
  digitalWrite(pinBlue, blue);
}

void connect(){
  rgb(1,0,0); //led merah
  while (WiFi.status() != WL_CONNECTED){
    delay(500);
  }
  rgb(0,1,0); //wifi connected led hijau

  client.setWill("tugasiot/status/12345678", "offline", true, 1);
  while(!client.connect("billah-farmku", "tugasiot2025", "9c3tbJgo4D8UTAlS")){
    delay(500);
  }
  rgb(0,0,1); //mqtt connected led biru
  client.publish("tugasiot/status/12345678", "online", true, 1);
  client.subscribe("tugasiot/#", 1);
}