#include <WiFi.h>
#include <MQTT.h>
#include <ESP32Servo.h>
#include <NusabotSimpleTimer.h>
#include "DHTesp.h"

WiFiClient net;
MQTTClient client;
Servo servo;
NusabotSimpleTimer timer;
DHTesp dhtSensor;

const char ssid[] = "Wokwi-GUEST";
const char pass[] = "";

const int pinRed = 2;
const int pinGreen = 4;
const int pinBlue = 16;
const int pinLED = 13;
const int pinServo = 18;
const int pinPot = 33;
const int pinDHT = 25;

int pot, oldPot = 0;
String serial_number = "12345678";

void setup() {
  Serial.begin(9600);
  pinMode(pinRed, OUTPUT);
  pinMode(pinGreen, OUTPUT);
  pinMode(pinBlue, OUTPUT);
  pinMode(pinLED, OUTPUT);
  pinMode(pinPot, INPUT);

  dhtSensor.setup(pinDHT, DHTesp::DHT22);
  servo.attach(pinServo, 500, 2400);

  WiFi.begin(ssid, pass);
  client.begin("kelasiot76.cloud.shiftr.io", net);
  client.onMessage(subscribe);

  timer.setInterval(1000, publishPot);
  timer.setInterval(10000, publishDHT);

  connect();
}

void loop() {
  client.loop();
  timer.run();

  if (!client.connected()) {
    connect();
  }
  delay(10);
}

void subscribe(String &topic, String &data) {
  Serial.print("Topic:  ");
  Serial.println(topic);
  Serial.print("Data:   ");
  Serial.println(data);

  if (topic == "KELASIOT/KONTROL/" + serial_number + "/LED") {
    if (data == "NYALA") {
      digitalWrite(pinLED, HIGH);
    } else if (data == "MATI") {
      digitalWrite(pinLED, LOW);
    }
  }

  if (topic == "KELASIOT/KONTROL/" + serial_number + "/SERVO1") {
    int posServo = data.toInt();
    servo.write(posServo);
    Serial.println(posServo);
  }
}

void publishPot() {
  pot = analogRead(pinPot);
  if (pot != oldPot) {
    client.publish("KELASIOT/SENSOR/" + serial_number + "/POTENSIOMETER", String(pot), false, 0);
    oldPot = pot;
  }
}

void publishDHT() {
  TempAndHumidity data = dhtSensor.getTempAndHumidity();
  client.publish("KELASIOT/SENSOR/" + serial_number + "/SUHU", String(data.temperature, 2), true, 1);
  client.publish("KELASIOT/SENSOR/" + serial_number + "/KELEMBAPAN", String(data.humidity, 1), true, 1);

  Serial.println("Temp: " + String(data.temperature, 2) + "°C");
  Serial.println("Humidity: " + String(data.humidity, 1) + "%");
  Serial.println("---");
}

void rgb(bool red, bool green, bool blue) {
  digitalWrite(pinRed, red);
  digitalWrite(pinGreen, green);
  digitalWrite(pinBlue, blue);
}

void connect() {
  rgb(1, 0, 0); // LED merah menyala
  Serial.print("Menghubungkan ke WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    Serial.print(".");
    delay(500);
  }
  Serial.println("\nBerhasil terhubung ke WiFi");
  rgb(0, 1, 0); // LED hijau menyala

  client.setWill("KELASIOT/STATUS/SERIALNUMBER-12345678", "OFFLINE", true, 1);

  Serial.print("Menghubungkan ke broker MQTT...");
  while (!client.connect("ESP32Client", "kelasiot76", "JVxbR1CjvQJbblrJ")) {
    Serial.println("Gagal, mencoba lagi...");
    delay(500);
  }
  Serial.println("Berhasil terhubung ke broker MQTT");
  rgb(0, 0, 1); // LED biru menyala

  client.publish("KELASIOT/STATUS/SERIALNUMBER-12345678", "ONLINE", true, 1);
  client.subscribe("KELASIOT/KONTROL/#", 1);
}