#include <WiFi.h>
#include <NTPClient.h>
#include <WiFiUdp.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

// WiFi Credentials (Update these)
const char* ssid     = "Aietel+arvi_6035";
const char* password = "air26289";

// OLED Display
#define SCREEN_WIDTH  128
#define SCREEN_HEIGHT 64
#define OLED_RESET    -1  // Reset pin (or -1 if sharing Arduino reset pin)

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

// NTP Configuration
WiFiUDP ntpUDP;
NTPClient timeClient(ntpUDP, "pool.ntp.org", 19800, 60000); // UTC +5:30 for IST

int clockCenterX = SCREEN_WIDTH / 2;
int clockCenterY = ((SCREEN_HEIGHT - 16) / 2) + 16; // Adjust for OLED height
int clockRadius  = 33;

void setup() {
  Serial.begin(115200);

  // Connect to WiFi
  WiFi.begin(ssid, password);
  Serial.print("Connecting to WiFi...");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("\nConnected to WiFi");

  // Initialize NTP client
  timeClient.begin();

  // Initialize OLED display
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println(F("SSD1306 allocation failed"));
    while (1);
  }

  display.clearDisplay();
  display.setTextColor(SSD1306_WHITE);
  display.setTextSize(1);
  display.display();
}

void loop() {
  timeClient.update(); // Fetch time from the internet

  int currentHour = timeClient.getHours();
  int currentMinute = timeClient.getMinutes();
  int currentSecond = timeClient.getSeconds();

  display.clearDisplay(); // Clear screen before drawing

  // Draw clock frame
  analogClockFrame(currentHour, currentMinute, currentSecond);

  // Print static text
  printText("Arvind", 10, 10); 

  display.display();  // Show content
  delay(1000);
}

void analogClockFrame(int hour, int minute, int second) {
  display.drawCircle(clockCenterX, clockCenterY, 2, SSD1306_WHITE);

  // Draw Hour Ticks
  for (int z = 0; z < 360; z += 30) {
    float angle = z * (PI / 180);
    int x2 = clockCenterX + (sin(angle) * clockRadius);
    int y2 = clockCenterY - (cos(angle) * clockRadius);
    int x3 = clockCenterX + (sin(angle) * (clockRadius - 5));
    int y3 = clockCenterY - (cos(angle) * (clockRadius - 5));
    display.drawLine(x2, y2, x3, y3, SSD1306_WHITE);
  }

  // Draw Hands
  drawClockHand(hour * 30 + minute / 2, clockRadius - 15); // Hour hand
  drawClockHand(minute * 6, clockRadius - 8);              // Minute hand
  drawClockHand(second * 6, clockRadius - 5);              // Second hand
}

void drawClockHand(int angleDegree, int length) {
  float angle = angleDegree * (PI / 180);
  int x = clockCenterX + (sin(angle) * length);
  int y = clockCenterY - (cos(angle) * length);
  display.drawLine(clockCenterX, clockCenterY, x, y, SSD1306_WHITE);
}

void printText(String text, int x, int y) {
  display.setCursor(x, y);
  display.print(text);
}