#include "DHT.h"
#include <ArduinoJson.h>
#include <WiFi.h>
#include "PubSubClient.h"
#include <LiquidCrystal_I2C.h>
#include <Adafruit_Sensor.h>
#include <ESP32Servo.h>

// Cấu hình servo
const int servoPin = 15;
Servo servo;
int pos = 0;

// Cấu hình cảm biến DHT22
#define DHTPIN 33  
#define DHTTYPE DHT22  

DHT dht(DHTPIN, DHTTYPE);

// Cấu hình LCD
#define I2C_ADDR    0x27
#define LCD_COLUMNS 20
#define LCD_LINES   4

LiquidCrystal_I2C lcd(I2C_ADDR, LCD_COLUMNS, LCD_LINES);

// Thông tin thiết bị IoT
int ledPin = 18;  

// Thông tin MQTT Broker
const char *MQTTServer = "broker.emqx.io";
const char *MQTT_Topic = "conghoa/voice_control"; // Topic để điều khiển LED
const char *MQTT_Topic2 = "conghoa/detection_drowsy"; // Topic cảnh báo ngủ gật
const char *MQTT_Topic3 = "conghoa/curtain"; // Topic cảnh báo ngủ gật

const char *MQTT_ID = "conghoa_004";
int Port = 1883;

WiFiClient espClient;
PubSubClient client(espClient);

// Kết nối WiFi
void WIFIConnect()
{
  Serial.println("Connecting to SSID: Wokwi-GUEST");
  WiFi.begin("Wokwi-GUEST", "");
  while (WiFi.status() != WL_CONNECTED)
  {
    delay(500);
    Serial.print(".");
  }
  Serial.println("\nWiFi connected");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
}

// Kết nối lại MQTT nếu bị mất
void MQTT_Reconnect()
{
  while (!client.connected())
  {
    if (client.connect(MQTT_ID))
    {
      Serial.print("MQTT Topic: ");
      Serial.print(MQTT_Topic);
      Serial.print(" connected");
      client.subscribe(MQTT_Topic);
      Serial.println("");

      Serial.print("MQTT Topic: ");
      Serial.print(MQTT_Topic2);
      Serial.print(" connected");
      client.subscribe(MQTT_Topic2);
      Serial.println("");

      Serial.print("MQTT Topic: ");
      Serial.print(MQTT_Topic3);
      Serial.print(" connected");
      client.subscribe(MQTT_Topic3);
      Serial.println("");
    }
    else
    {
      Serial.print("Failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

// Hàm callback xử lý MQTT
void callback(char *topic, byte *message, unsigned int length)
{
  Serial.print("Message arrived on topic: ");
  Serial.println(topic);
  String stMessage;

  for (int i = 0; i < length; i++)
  {
    stMessage += (char)message[i];
  }
  Serial.println(stMessage);
  
  // Xử lý Topic bật tắt LED bằng giọng nói
  if (String(topic) == "conghoa/voice_control")
  {
    if(stMessage == "true"){
      digitalWrite(ledPin, HIGH);
    }else if (stMessage == "false"){
      digitalWrite(ledPin, LOW);
    }
  }

  // Xử lý Topic đóng mở rèm cửa
  if (String(topic) == "conghoa/curtain")
  {
    if(stMessage == "off"){
      for (pos = 0; pos <= 180; pos += 1) {
        servo.write(pos);
        delay(15);
      }
    }else if (stMessage == "on"){
      for (pos = 180; pos >= 0; pos -= 1) {
        servo.write(pos);
        delay(15);
      }
    }
  }
}

// Task để gửi dữ liệu DHT
void sendDHTTask(void *pvParameters)
{
  while (1)
  {
    float h = dht.readHumidity();
    float t = dht.readTemperature();
    
    if (!isnan(h) && !isnan(t))
    {
      String payload = "{ \"temp\": " + String(t) + ", \"hum\": " + String(h) + " }";
      client.publish("conghoa/dht", payload.c_str());
      // Serial.println("Sent DHT data: " + payload);
    }
    
    vTaskDelay(10000);  // Chờ 10 giây
  }
}

void setup()
{
  Serial.begin(115200);
  WIFIConnect();
  client.setServer(MQTTServer, Port);
  client.setCallback(callback);

  lcd.init();
  lcd.backlight();
  lcd.setCursor(0, 0);
  lcd.print("SMART HOUSE");

  pinMode(ledPin, OUTPUT);
  dht.begin();

  // Tạo task riêng cho DHT
  xTaskCreatePinnedToCore(
    sendDHTTask,    // Hàm thực hiện task
    "DHT Task",     // Tên task
    4096,           // Kích thước stack (4KB)
    NULL,           // Tham số
    1,              // Độ ưu tiên (1 là mức thấp)
    NULL,           // Handle (không cần thiết)
    1               // Chạy trên core 1
  );

  // Cấu hình servo
  servo.attach(servoPin, 500, 2400);

  // Mặc định đóng rèm cửa
  for (pos = 0; pos <= 180; pos += 1) {
    servo.write(pos);
    delay(15);
  }
}

void loop()
{
  if (!client.connected())
  {
    MQTT_Reconnect();
  }
  client.loop();
  delay(10);
}