/*Alla pressione del pulsante si attiva o disattiva il lampeggo di un led*/
#include "urutils.h"
int led = 13;
byte pulsante =12;
byte stato= LOW;  // variabile globale che memorizza lo stato del pulsante
volatile bool pressed;
#define DEBOUNCETIME 50
DiffTimer debounce;
 
void setup() {
  Serial.begin(115200);
  pinMode(led, OUTPUT);
  pinMode(pulsante, INPUT);
  attachInterrupt(digitalPinToInterrupt(pulsante), switchPressed, RISING );  
  pressed = false;
}

// Interrupt Service Routine (ISR)
void switchPressed ()
{
 if(!pressed){// evita detach durante un attach nel loop
    // disarma l'interrupt
    // può essere omessa se viene tolto l'attach() nel loop()
    detachInterrupt(digitalPinToInterrupt(pulsante));
    // arma il timer
    pressed = true; 
 }
}  // end of switchPressed

void waitUntilInputChange()
{
    if (pressed){ 
      debounce.start();// aggiorna il millis() interno solo alla prima di molte chiamate consecutive
      if(debounce.get() > DEBOUNCETIME  && digitalRead(pulsante) == LOW){// disarmo del timer al timeout
        debounce.stop(); // disarmo del timer
        debounce.reset();
        // fronte di discesa
        stato = !stato; // logica da attivare sul fronte (toggle)
        // riarma l'interrupt
        // può essere omessa se eviene tolto il detach() nella ISR
        attachInterrupt(digitalPinToInterrupt(pulsante), switchPressed, RISING ); 
        pressed = false; // disarma il timer
      }
    }
}
// loop principale
void loop() {
	waitUntilInputChange();
	digitalWrite(led, stato);   	// inverti lo stato precedente del led
  delay(10);
}