// amount of used 74HC165 chips
#define AMOUNT_IC 1
#define DATA_WIDTH AMOUNT_IC * 8

const uint8_t DataPin = 2;  // 74HC595 SER (14) pin
const uint8_t LatchPin = 3; // 74HC595 RCLK (12) pin
const uint8_t ClockPin = 4; // 74HC595 SRCLK (11) pin
#define PIN_PL  8 // 74HC165 latch (1) pin
#define PIN_CE  5 // 74HC165 clock enable (13) pin
#define PIN_Q7  6 // 74HC165 data (9) pin
#define PIN_CLK 7 // 74HC165 clock (2) pin

unsigned long pinValues, oldPinValues;

void setup() {
  Serial.begin(9600);
  // 74HC165 connections
  pinMode(PIN_PL, OUTPUT);
  pinMode(PIN_CE, OUTPUT);
  pinMode(PIN_CLK, OUTPUT);
  pinMode(PIN_Q7, INPUT);
  // 74HC595 connections
  pinMode(LatchPin, OUTPUT);
  pinMode(DataPin, OUTPUT);
  pinMode(ClockPin, OUTPUT);
  digitalWrite(PIN_CLK, LOW);
  digitalWrite(PIN_PL, HIGH);
  digitalWrite(LatchPin, HIGH);

  pinValues = readShiftRegisters();
  printByte();
  oldPinValues = pinValues;
}

void loop() {
  pinValues = readShiftRegisters();
  byte ledData = 0;
  for (byte i = 0; i < DATA_WIDTH; i++) {
    if (pinValues & (1UL << i)) {
      ledData |= (1 << i);
    }
  }

  writeShiftRegister(ledData);

  if (pinValues != oldPinValues) {
    printByte();
    oldPinValues = pinValues;
  }
  delay(500);
}

unsigned long readShiftRegisters() {
  long bitVal;
  unsigned long bytesVal = 0;

  digitalWrite(PIN_CE, HIGH);
  digitalWrite(PIN_PL, LOW);
  delayMicroseconds(5);
  digitalWrite(PIN_PL, HIGH);
  digitalWrite(PIN_CE, LOW);

  for (byte i = 0; i < DATA_WIDTH; i++) {
    bitVal = digitalRead(PIN_Q7);
    bytesVal |= (bitVal << ((DATA_WIDTH - 1) - i));
    digitalWrite(PIN_CLK, HIGH);
    delayMicroseconds(5);
    digitalWrite(PIN_CLK, LOW);
  }
  return (bytesVal);
}

void writeShiftRegister(byte data) {
  digitalWrite(LatchPin, LOW);
  shiftOut(DataPin, ClockPin, MSBFIRST, data);
  digitalWrite(LatchPin, HIGH);
}

void printByte() {
  for (byte i = 0; i <= DATA_WIDTH - 1; i++) {
    Serial.print("D" + String(i + 1) + " ");
  }
  Serial.println("");
  for (byte i = 0; i <= DATA_WIDTH - 1; i++) {
    Serial.print(pinValues >> i & 1, BIN);
    Serial.print("  ");
  }
  Serial.println("\n");
}