#include <WiFi.h>
#include <PubSubClient.h>


// Configuration WiFi et MQTT
const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqttServer = "broker.emqx.io";
const int port = 1883;
const char* TOPIC = "serfek";

// Objets WiFi et MQTT
WiFiClient espClient;
PubSubClient client(espClient);

// Broche pour la LED
const int ledPin = 27;

void setup() {
  Serial.begin(115200);
  randomSeed(analogRead(0));

  // Connexion WiFi
  connectToWiFi();

  // Initialisation MQTT
  client.setServer(mqttServer, port);
  client.setCallback(callback);

  // Configuration de la broche LED
  pinMode(ledPin, OUTPUT);
}

void connectToWiFi() {
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  Serial.print("Connecting to ");
  Serial.println(ssid);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("\nWiFi connected");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
}

void reconnectMQTT() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    String clientId = "clientId-" + String(random(1000));
    if (client.connect(clientId.c_str())) {
      Serial.println(" connected");
      client.subscribe(TOPIC);
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(". Retrying in 5 seconds...");
      delay(5000);
    }
  }
}

void callback(char* topic, byte* message, unsigned int length) {
  Serial.print("Message received on topic: ");
  Serial.print(topic);
  Serial.print(". Message: ");

  String payload;
  for (int i = 0; i < length; i++) {
    payload += (char)message[i];
    Serial.print((char)message[i]);
  }
  Serial.println();

  if (String(topic) == TOPIC) {
    if (payload == "on") {
      Serial.println("Turning LED ON");
      digitalWrite(ledPin, HIGH);
    } else if (payload == "off") {
      Serial.println("Turning LED OFF");
      digitalWrite(ledPin, LOW);
    }
  }
}

void loop() {
  if (!client.connected()) {
    reconnectMQTT();
  }
  client.loop();
}