#include <Wire.h>
#include <RTClib.h>
//#include <DS3231.h>
#include <SPI.h>

// 74HC595 11 CKL, 12 LATCH, 14 DATA
#define DATA_PIN 4
#define CLOCK_PIN 2
#define LATCH_PIN 3
#define AM_LED 11
#define PM_LED 12
#define COLON_LED 13

RTC_DS3231 rtc;
#define ADDRESS 0x68

byte monthChars[12][3] = {
  {B01000111, B00001000, B01101010},
  {B00111000, B00110000, B01100000},
  {B00001001, B00001000, B01111010},
  {B00001000, B00011000, B01111010},
  {B00001001, B00001000, B01000100},
  {B01000111, B01000001, B01101010},
  {B01000111, B01000001, B01110001},
  {B00001000, B01000001, B00000100},
  {B00100100, B00110000, B00011000},
  {B00000001, B00110001, B01110000},
  {B01101010, B00000001, B01100011},
  {B01000010, B00110000, B00110001}
};

byte segmentChars[] = {
  B00000001,
  B01001111,
  B00010010,
  B00000110,
  B01001100,
  B00100100,
  B01100000,
  B00001111,
  B00000000,
  B00001100
};

void setup() {
  pinMode(DATA_PIN, OUTPUT);
  pinMode(CLOCK_PIN, OUTPUT);
  pinMode(LATCH_PIN, OUTPUT);
  pinMode(AM_LED, OUTPUT);
  pinMode(PM_LED, OUTPUT);
  pinMode(COLON_LED, OUTPUT);
  Wire.begin();
  rtc.begin();
  if (rtc.lostPower()) {
    rtc.adjust(DateTime(F(__DATE__), F(__TIME__)));
  }
}

void loop() {
  DateTime now = rtc.now();
  int year = now.year();
  int month = now.month();
  int day = now.day();
  int hour24 = now.hour();
  int hour = hour24 % 12;
  if (hour == 0) hour = 12;
  int minute = now.minute();
  bool isPM = hour24 >= 12;

  byte displayData[13];

  for (int i = 0; i < 3; i++) {
    displayData[i] = monthChars[month - 1][i];
  }

  displayData[3] = segmentChars[day / 10];
  displayData[4] = segmentChars[day % 10];
  displayData[5] = segmentChars[year / 1000];
  displayData[6] = segmentChars[(year % 1000) / 100];
  displayData[7] = segmentChars[(year % 100) / 10];
  displayData[8] = segmentChars[year % 10];
  displayData[9] = segmentChars[hour / 10];
  displayData[10] = segmentChars[hour % 10];
  displayData[11] = segmentChars[minute / 10];
  displayData[12] = segmentChars[minute % 10];

  digitalWrite(AM_LED, isPM);
  digitalWrite(PM_LED, !isPM);
  digitalWrite(COLON_LED, !(now.second() % 2 == 0));

  updateDisplay(displayData);
  delay(1000);
}

void updateDisplay(byte *data) {
  digitalWrite(LATCH_PIN, LOW);
  for (int i = 12; i >= 0; i--) {
    shiftOut(DATA_PIN, CLOCK_PIN, LSBFIRST, data[i]);
  }
  digitalWrite(LATCH_PIN, HIGH);
}