#include <HX711.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <Keypad.h>

#define TRIG_PIN 12
#define ECHO_PIN 13
#define DOUT A1
#define CLK A0

HX711 scale;
LiquidCrystal_I2C lcd(0x27, 16, 2);

// Keypad config
const byte ROWS = 4;
const byte COLS = 4;
char keys[ROWS][COLS] = {
  {'1','2','3','A'},
  {'4','5','6','B'},
  {'7','8','9','C'},
  {'*','0','#','D'}
};
byte rowPins[ROWS] = {10,9,8,7};
byte colPins[COLS] = {6,5,4,3};
Keypad keypad = Keypad(makeKeymap(keys), rowPins, colPins, ROWS, COLS);

// Variables
float tinggi_cm = 0;
float berat_kg = 0;
float bmi = 0;
float bfp = 0;
int umur = 0;
char gender = 'M'; // default 'M' untuk pria

void setup() {
  Serial.begin(9600);
  lcd.begin();
  lcd.backlight();

  scale.begin(DOUT, CLK);
  scale.set_scale(); // sesuaikan jika sudah dikalibrasi
  scale.tare();

  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);

  lcd.clear();
  lcd.setCursor(0,0);
  lcd.print("BMI & BFP Meter");
  delay(2000);
}

float ukurTinggi() {
  digitalWrite(TRIG_PIN, LOW);
  delayMicroseconds(2);
  digitalWrite(TRIG_PIN, HIGH);
  delayMicroseconds(10);
  digitalWrite(TRIG_PIN, LOW);
  long durasi = pulseIn(ECHO_PIN, HIGH);
  float cm = durasi * 0.034 / 2;
  return cm;
}

float ukurBerat() {
  float berat = scale.get_units(10);
  if (berat < 0) berat = 0;
  return berat;
}

int inputAngka(String pesan) {
  String input = "";
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print(pesan);
  lcd.setCursor(0, 1);
  while (true) {
    char key = keypad.getKey();
    if (key) {
      if (key >= '0' && key <= '9') {
        input += key;
        lcd.print(key);
      } else if (key == '#') {
        break;
      }
    }
  }
  return input.toInt();
}

char inputGender() {
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Jenis Kelamin:");
  lcd.setCursor(0, 1);
  lcd.print("A=Pria B=Wanita");
  while (true) {
    char key = keypad.getKey();
    if (key == 'A') return 'M';
    else if (key == 'B') return 'F';
  }
}

void loop() {
  umur = inputAngka("Masukkan umur:");
  gender = inputGender();

  lcd.clear();
  lcd.print("Ukur tinggi...");
  delay(2000);
  tinggi_cm = ukurTinggi();

  lcd.clear();
  lcd.print("Ukur berat...");
  delay(2000);
  berat_kg = ukurBerat();

  float tinggi_m = tinggi_cm / 100.0;
  bmi = berat_kg / (tinggi_m * tinggi_m);

  if (gender == 'M')
    bfp = 1.20 * bmi + 0.23 * umur - 16.2;
  else
    bfp = 1.20 * bmi + 0.23 * umur - 5.4;

  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("BMI: ");
  lcd.print(bmi, 1);
  lcd.setCursor(0, 1);
  lcd.print("BFP: ");
  lcd.print(bfp, 1);
  
  delay(10000); // tampilkan selama 10 detik
}