#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <DHT.h>
#include <ESP32Servo.h>

// WiFi Credentials
const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqtt_server = "broker.hivemq.com"; // Public MQTT Broker

WiFiClient espClient;
PubSubClient client(espClient);

// Pin definitions
#define DHTPIN 4
#define DHTTYPE DHT22
#define SOIL_MOISTURE_PIN 34
#define RELAY_PIN 18
#define LED_PIN 2
#define SERVO_PIN 5

// Thresholds
const int moistureThreshold = 2000;
const int tempThreshold = 10;
const int humidityThreshold = 80;
bool killSwitch = false;

// Components
DHT dht(DHTPIN, DHTTYPE);
LiquidCrystal_I2C lcd(0x27, 20, 4);
Servo waterPump;

void setup() {
  Serial.begin(115200);
  
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("WiFi connected");
  
  client.setServer(mqtt_server, 1883);
  client.setCallback(mqttCallback);
  reconnectMQTT();
  
  dht.begin();
  lcd.begin(16, 2);
  lcd.init();
  lcd.backlight();
  lcd.setCursor(0, 0);
  lcd.print("Smart Irrigation Sys");
  
  waterPump.attach(SERVO_PIN);
  waterPump.write(0);
  
  pinMode(SOIL_MOISTURE_PIN, INPUT);
  pinMode(RELAY_PIN, OUTPUT);
  pinMode(LED_PIN, OUTPUT);
  
  digitalWrite(RELAY_PIN, HIGH);
  digitalWrite(LED_PIN, LOW);
}

void mqttCallback(char* topic, byte* payload, unsigned int length) {
  payload[length] = '\0';
  String message = String((char*)payload);
  if (strcmp(topic, "irrigation/killswitch") == 0) {
    killSwitch = (message == "1");
  }
}

void reconnectMQTT() {
  while (!client.connected()) {
    if (client.connect("ESP32_Client")) {
      client.subscribe("irrigation/killswitch");
    } else {
      delay(5000);
    }
  }
}

void startWatering() {
  waterPump.write(90);
  lcd.setCursor(0, 1);
  lcd.print("Watering ON ");
  Serial.println("Watering ON...");
  digitalWrite(LED_PIN, HIGH);
}

void stopWatering() {
  waterPump.write(0);
  lcd.setCursor(0, 1);
  lcd.print("Watering OFF");
  Serial.println("Watering OFF");
  digitalWrite(LED_PIN, LOW);
}

void loop() {
  if (!client.connected()) {
    reconnectMQTT();
  }
  client.loop();
  
  int soilMoistureValue = analogRead(SOIL_MOISTURE_PIN);
  float temperature = dht.readTemperature();
  float humidity = dht.readHumidity();

  Serial.printf("Moisture: %d, Temp: %.2fC, Hum: %.2f%%\n", soilMoistureValue, temperature, humidity);

  lcd.setCursor(0, 1);
  lcd.printf("Temp: %.2fC Hum: %.2f%%", temperature, humidity);

  // Send data to MQTT
  char msg[100];
  snprintf(msg, sizeof(msg), "{\"moisture\": %d, \"temp\": %.2f, \"humidity\": %.2f}", soilMoistureValue, temperature, humidity);
  client.publish("irrigation/data", msg);

  if (!killSwitch && soilMoistureValue < moistureThreshold && temperature > tempThreshold && humidity < humidityThreshold) {
    digitalWrite(RELAY_PIN, LOW);
    startWatering();
  } else {
    digitalWrite(RELAY_PIN, HIGH);
    stopWatering();
  }
  delay(2000);
}