/*****************************************
 * ATTINY_SIGNAL_SIMULE_BAL - 30/11/2016 *
 * ***************************************
 * Christian BEZANGER - Domaine public
 * Ce programme simule le fonctionnement d un signal lumineux a trois
 * feux d un B.A.L Block Automatique Lumineux. Il n'assure pas
 * l'espacement des trains. Lorsque la loco declenche le premier ILS,
 * le signal se met au rouge. Lorsque la loco declenche le deuxieme
 * ILS, le signal se met a l orange pour une duree egale a celle du
 * rouge, puis repasse au vert.
 */

 /*  VARIABLES
  *  --------------------------------------------------------------
  *  debRouge : temps de debut du feu rouge
  *  finRouge : temps de fin du feu rouge
  *  dureeRouge ; duree du feu rouge
  *  debOrange : temps de debut du feu orange
  *  flagOrange : booleen 0 si feu orange eteint, 1 si allume
  */

  /* BRANCHEMENTS
   * --------------------------------------------------------------
   * ILS E (entree) sur 3
   * ILS S (sortie) sur 4
   * feu vert sur 0
   * feu rouge sur 1
   * feu orange sur 2
   */

#define Led_ON LOW   // Mettre HIGH si signal a cathodes communes
#define Led_OFF HIGH  // Mettre LOW si signal a cathodes communes

const byte ILS_entree = 3;
const byte ILS_sortie = 4;
const byte feu_vert = 0;
const byte feu_rouge = 1;
const byte feu_orange = 2;
unsigned long debRouge = 0;
unsigned long finRouge = 0;
unsigned long debOrange = 0;
unsigned long dureeRouge;
boolean flagOrange = false;

void setup() {
  pinMode(ILS_entree, INPUT_PULLUP);
  pinMode(ILS_sortie, INPUT_PULLUP);
  pinMode(feu_vert, OUTPUT);
  pinMode(feu_rouge, OUTPUT);
  pinMode(feu_orange, OUTPUT);
  // Initialisation du signal allume par Led_ON
  digitalWrite(feu_vert, Led_ON);
  digitalWrite(feu_rouge, Led_OFF);
  digitalWrite(feu_orange, Led_OFF);
  }

void loop() {
  // Surveillance de l ILS d entree
  while (digitalRead(ILS_entree) == HIGH)
  {
    // ILS E non declenche
    if (flagOrange)
    {
      if ((millis() - debOrange) > dureeRouge)
      {
        digitalWrite(feu_orange, Led_OFF);
        flagOrange = false;
        digitalWrite(feu_vert, Led_ON);
      }
    }
   }
  // ILS E declenche
  digitalWrite(feu_vert, Led_OFF);
  digitalWrite(feu_orange, Led_OFF);
  flagOrange = false;
  digitalWrite(feu_rouge, Led_ON);
  debRouge = millis();
  // Surveillance de l ILS de sortie
  while (digitalRead(ILS_sortie) == HIGH)
  {
    // ILS S non declenche, ne rien faire
  }
  // ILS S declenche
  finRouge = millis();
  dureeRouge = finRouge - debRouge;
  digitalWrite(feu_rouge, Led_OFF);
  digitalWrite(feu_orange, Led_ON);
  flagOrange = true;
  debOrange = millis();

}