Wokwi - Online ESP32, STM32, Arduino Simulator

#include <WiFi.h>
#include <WiFiClient.h>
#include <WebServer.h>
#include <uri/UriBraces.h>
#include <MQTT.h>

#define WIFI_SSID "Wokwi-GUEST"
#define WIFI_PASSWORD ""
#define WIFI_CHANNEL 6

#define MQTT_HOST "kailaerb.cloud.shiftr.io"
#define MQTT_USER "public"
#define MQTT_PASSWORD "public"

WiFiClient net;
MQTTClient client;
WebServer server(80);

const int LED1 = 26;
const int LED2 = 27;

bool led1State = false;
bool led2State = false;

void sendHtml() {
  String response = R"(
    <!DOCTYPE html><html>
      <head>
        <title>ESP32 Web Server Demo</title>
        <meta name="viewport" content="width=device-width, initial-scale=1">
        <style>
          html { font-family: sans-serif; text-align: center; }
          body { display: inline-flex; flex-direction: column; }
          h1 { margin-bottom: 1.2em; } 
          h2 { margin: 0; }
          div { display: grid; grid-template-columns: 1fr 1fr; grid-template-rows: auto auto; grid-auto-flow: column; grid-gap: 1em; }
          .btn { background-color: #5B5; border: none; color: #fff; padding: 0.5em 1em;
                 font-size: 2em; text-decoration: none }
          .btn.OFF { background-color: #333; }
        </style>
      </head>
            
      <body>
        <h1>ESP32 Web Server</h1>

        <div>
          <h2>LED 1</h2>
          <a href="/toggle/1" class="btn LED1_TEXT">LED1_TEXT</a>
          <h2>LED 2</h2>
          <a href="/toggle/2" class="btn LED2_TEXT">LED2_TEXT</a>
        </div>
      </body>
    </html>
  )";
  response.replace("LED1_TEXT", led1State ? "ON" : "OFF");
  response.replace("LED2_TEXT", led2State ? "ON" : "OFF");
  server.send(200, "text/html", response);
}

void connectToMQTT() {
  Serial.print("Connecting to MQTT...");
  while (!client.connect("esp32-client", MQTT_USER, MQTT_PASSWORD)) {
    Serial.print(".");
    delay(1000);
  }
  Serial.println(" connected!");

  client.subscribe("esp32/led1");
  client.subscribe("esp32/led2");
}

void messageReceived(String &topic, String &payload) {
  Serial.println("MQTT Message received:");
  Serial.println("Topic: " + topic);
  Serial.println("Payload: " + payload);

  if (topic == "esp32/led1") {
    led1State = (payload == "ON");
    digitalWrite(LED1, led1State);
  } else if (topic == "esp32/led2") {
    led2State = (payload == "ON");
    digitalWrite(LED2, led2State);
  }
}

void setup(void) {
  // inisialisasi serial output
  Serial.begin(115200);
  pinMode(LED1, OUTPUT);
  pinMode(LED2, OUTPUT);

  // inisialisasi WiFi
  WiFi.begin(WIFI_SSID, WIFI_PASSWORD, WIFI_CHANNEL);
  Serial.print("Connecting to WiFi ");
  Serial.print(WIFI_SSID);
  while (WiFi.status() != WL_CONNECTED) {
    delay(100);
    Serial.print(".");
  }
  Serial.println(" Connected!");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());

  // Inisialisasi MQTT
  client.begin(MQTT_HOST, net);
  client.onMessage(messageReceived);
  connectToMQTT();

  server.on("/", sendHtml);

  server.on(UriBraces("/toggle/{}"), []() {
    String led = server.pathArg(0);
    Serial.print("Toggle LED #");
    Serial.println(led);

    if (led == "1") {
      led1State = !led1State;
      digitalWrite(LED1, led1State);
      client.publish("esp32/led1", led1State ? "ON" : "OFF");
    } else if (led == "2") {
      led2State = !led2State;
      digitalWrite(LED2, led2State);
      client.publish("esp32/led2", led2State ? "ON" : "OFF");
    }

    sendHtml();
  });

  server.begin();
  Serial.println("HTTP server started");
}

void loop(void) {
  client.loop();
  if (!client.connected()) {
    connectToMQTT();
  }

  server.handleClient();
}