#include <WiFi.h>
#include <PubSubClient.h>
#include <DHTesp.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <ESP32Servo.h>

// Pin definitions
#define ACS712_PIN 34
#define ZMPT101B_PIN 35
#define DHT_PIN 32
#define BUZZER_PIN 25
#define SERVO_PIN 13
#define POT_FIRE_PIN 33
#define RED_LED_PIN 2
#define BLUE_LED_PIN 4

// ADC parameters
#define ADC_RESOLUTION 4095.0
#define ADC_VREF_mV 5000.0

// WiFi and MQTT configuration
const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqtt_server = "test.mosquitto.org";

// Device instances
LiquidCrystal_I2C lcd(0x27, 20, 4);
DHTesp dht;
Servo servoMotor;
WiFiClient espClient;
PubSubClient client(espClient);

// Variables
unsigned long lastMsg = 0;
unsigned long fireStartTime = 0;
bool fuegoActivo = false;
float prevTemp = 0;
float prevHum = 0;
float prevVolt = 0;
float prevCurr = 0;
bool prevFire = false;

void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  randomSeed(micros());

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }
  Serial.println();

  // Handle incoming commands
  String message = "";
  for (int i = 0; i < length; i++) {
    message += (char)payload[i];
  }

  if (String(topic) == "/monitoring/control") {
    if (message == "buzzer_on") {
      activarBuzzer();
    } else if (message == "buzzer_off") {
      desactivarBuzzer();
    } else if (message == "servo_activate") {
      activarServo();
    }
  }
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    String clientId = "ESP32Client-";
    clientId += String(random(0xffff), HEX);
    
    if (client.connect(clientId.c_str())) {
      Serial.println("connected");
      client.publish("/monitoring/status", "Monitoring system online");
      client.subscribe("/monitoring/control");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void activarBuzzer() {
  tone(BUZZER_PIN, 500);
}

void desactivarBuzzer() {
  noTone(BUZZER_PIN);
}

void activarServo() {
  servoMotor.detach();
  servoMotor.setPeriodHertz(50);
  servoMotor.attach(SERVO_PIN, 500, 2400);

  for (int pos = 0; pos <= 180; pos += 5) {
    servoMotor.write(pos);
    delay(10);
  }
  delay(500);
  for (int pos = 180; pos >= 0; pos -= 5) {
    servoMotor.write(pos);
    delay(10);
  }

  servoMotor.write(0);
  delay(100);
  servoMotor.detach();
}

void manejarFuego() {
  int valorPot = analogRead(POT_FIRE_PIN);
  float porcentaje = (valorPot / 4095.0) * 100;

  if (porcentaje > 50.0) {
    if (!fuegoActivo) {
      fireStartTime = millis();
      fuegoActivo = true;
      client.publish("/monitoring/alerts", "Fire detected!");
    }

    digitalWrite(RED_LED_PIN, millis() / 200 % 2);
    activarBuzzer();

    if (millis() - fireStartTime >= 4000) {
      digitalWrite(BLUE_LED_PIN, HIGH);
      client.publish("/monitoring/alerts", "Extinguisher activated!");
    } else {
      digitalWrite(BLUE_LED_PIN, LOW);
    }
  } else {
    if (fuegoActivo) {
      client.publish("/monitoring/alerts", "Fire extinguished");
    }
    fuegoActivo = false;
    digitalWrite(RED_LED_PIN, LOW);
    digitalWrite(BLUE_LED_PIN, LOW);
  }
}

void publishSensorData(float temp, float hum, float volt, float curr, bool fire) {
  unsigned long now = millis();
  if (now - lastMsg > 2000) {
    lastMsg = now;

    // Only publish if value changed significantly
    if (abs(temp - prevTemp) > 0.5) {
      String tempStr = String(temp, 2);
      client.publish("/monitoring/temperature", tempStr.c_str());
      prevTemp = temp;
    }
    
    if (abs(hum - prevHum) > 1.0) {
      String humStr = String(hum, 1);
      client.publish("/monitoring/humidity", humStr.c_str());
      prevHum = hum;
    }
    
    if (abs(volt - prevVolt) > 1.0) {
      String voltStr = String(volt, 2);
      client.publish("/monitoring/voltage", voltStr.c_str());
      prevVolt = volt;
    }
    
    if (abs(curr - prevCurr) > 0.1) {
      String currStr = String(curr, 2);
      client.publish("/monitoring/current", currStr.c_str());
      prevCurr = curr;
    }
    
    if (fire != prevFire) {
      client.publish("/monitoring/fire", fire ? "true" : "false");
      prevFire = fire;
    }
  }
}

void setup() {
  Serial.begin(115200);
  
  // Initialize LCD
  lcd.init();
  lcd.backlight();
  lcd.setCursor(2, 0);
  lcd.print("SISTEMA MONITOREO");
  delay(2000);
  lcd.clear();

  // Initialize pins
  pinMode(ACS712_PIN, INPUT);
  pinMode(ZMPT101B_PIN, INPUT);
  pinMode(BUZZER_PIN, OUTPUT);
  pinMode(POT_FIRE_PIN, INPUT);
  pinMode(RED_LED_PIN, OUTPUT);
  pinMode(BLUE_LED_PIN, OUTPUT);

  // Initialize DHT sensor
  dht.setup(DHT_PIN, DHTesp::DHT22);

  // Connect to WiFi and MQTT
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  // Read sensors
  int adcValue_V = analogRead(ZMPT101B_PIN);
  int adcValue_A = analogRead(ACS712_PIN);

  float voltaje = (0.0148 * adcValue_V) + 80.0;
  float voltage_mV = adcValue_A * (ADC_VREF_mV / ADC_RESOLUTION);
  float corriente = ((voltage_mV - 2500) / 2500.0) * 40.0;

  TempAndHumidity data = dht.getTempAndHumidity();
  float temp = data.temperature;
  float hum = data.humidity;

  // Publish data to MQTT
  publishSensorData(temp, hum, voltaje, corriente, fuegoActivo);

  // Display on LCD
  lcd.setCursor(0, 0);
  lcd.print("Volt: ");
  lcd.print(voltaje, 2);
  lcd.print("V ");

  lcd.setCursor(0, 1);
  lcd.print("Amp:  ");
  lcd.print(corriente, 2);
  lcd.print("A ");

  lcd.setCursor(0, 2);
  lcd.print("Temp: ");
  lcd.print(temp, 2);
  lcd.print("C  ");

  lcd.setCursor(0, 3);
  lcd.print("Humedad: ");
  lcd.print(hum, 1);
  lcd.print("%  ");

  // Check for alerts
  bool alertaElectrica = false;
  bool alertaClimatica = false;

  lcd.setCursor(14, 0);
  if (voltaje < 100.0 || voltaje > 110.0) {
    lcd.print(voltaje < 100.0 ? "BAJO " : "ALTO ");
    alertaElectrica = true;
  } else {
    lcd.print("     ");
  }

  lcd.setCursor(14, 1);
  if (corriente > 15.0) {
    lcd.print("ALTO ");
    alertaElectrica = true;
  } else {
    lcd.print("     ");
  }

  lcd.setCursor(14, 2);
  if (temp > 27.0 || temp < 18.0) {
    lcd.print(temp > 27.0 ? "CALOR" : "FRIO ");
    alertaClimatica = true;
  } else {
    lcd.print("     ");
  }

  lcd.setCursor(14, 3);
  if (hum < 40.0 || hum > 60.0) {
    lcd.print(hum < 40.0 ? "BAJA " : "ALTA ");
    alertaClimatica = true;
  } else {
    lcd.print("     ");
  }

  // Handle alerts
  if (alertaClimatica) {
    activarBuzzer();
    delay(500);
    desactivarBuzzer();
    client.publish("/monitoring/alerts", "Climate alert!");
  }

  if (alertaElectrica) {
    activarBuzzer();
    client.publish("/monitoring/alerts", "Electrical alert!");
  }

  if (!alertaClimatica && !alertaElectrica && !fuegoActivo) {
    desactivarBuzzer();
  }

  // Check for fire
  manejarFuego();

  delay(2000);
}